media-fonts/unifont/unifont-9.0.06.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit font toolchain-funcs xdg-utils
   7
   8 DESCRIPTION="GNU Unifont - a Pan-Unicode X11 bitmap iso10646 font"
   9 HOMEPAGE="http://unifoundry.com/"
  10 SRC_URI="mirror://gnu/${PN}/${P}/${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~alpha amd64 arm ia64 ppc ppc64 ~s390 sparc x86"
  15 IUSE="fontforge utils"
  16
  17 DEPEND="
  18         fontforge? (
  19                 app-text/bdf2psf
  20                 dev-lang/perl
  21                 dev-perl/GD[png(-)]
  22                 media-gfx/fontforge
  23                 x11-apps/bdftopcf
  24         )
  25 "
  26 RDEPEND="
  27         utils? (
  28                 dev-lang/perl
  29                 dev-perl/GD[png(-)]
  30         )
  31 "
  32
  33 src_prepare() {
  34         sed -i -e 's/install -s/install/' src/Makefile || die
  35         default
  36 }
  37
  38 src_compile() {
  39         if use fontforge || use utils; then
  40                 tc-export CC
  41                 xdg_environment_reset
  42                 makeargs=(
  43                         CFLAGS="${CFLAGS}"
  44                         BUILDFONT=$(usex fontforge 1 '')
  45                 )
  46                 emake -j1 "${makeargs[@]}"
  47         fi
  48 }
  49
  50 src_install() {
  51         makeargs+=(
  52                 DESTDIR="${ED%/}"
  53                 PCFDEST="${ED%/}${FONTDIR}"
  54                 TTFDEST="${ED%/}${FONTDIR}"
  55                 USRDIR=usr
  56         )
  57         use utils || makeargs+=( -C font )
  58         emake -j1 "${makeargs[@]}" install
  59         font_xfont_config
  60         font_fontconfig
  61 }