media-fonts/source-pro/source-pro-20141211.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5 inherit font
   6
   7 SANSV="2.010R-ro/1.065R-it"
   8 SERIFV="1.017R"
   9 CODEV="1.017R"
  10
  11 DESCRIPTION="Adobe's open source typeface family designed for UI environments"
  12 HOMEPAGE="https://adobe-fonts.github.io/source-sans-pro/
  13         https://adobe-fonts.github.io/source-serif-pro/
  14         https://adobe-fonts.github.io/source-code-pro/"
  15 SRC_URI="https://github.com/adobe-fonts/source-sans-pro/archive/${SANSV}.tar.gz -> source-sans-pro-${PV}.tar.gz
  16         https://github.com/adobe-fonts/source-serif-pro/archive/${SERIFV}.tar.gz -> source-serif-pro-${PV}.tar.gz
  17         https://github.com/adobe-fonts/source-code-pro/archive/${CODEV}.tar.gz -> source-code-pro-${PV}.tar.gz"
  18
  19 LICENSE="OFL-1.1"
  20 SLOT="0"
  21 KEYWORDS="~alpha amd64 arm ~arm64 ia64 ppc ppc64 ~sh sparc x86 ~x64-macos"
  22 IUSE="cjk"
  23
  24 RDEPEND="media-libs/fontconfig
  25         cjk? ( media-fonts/source-han-sans )"
  26
  27 S=${WORKDIR}
  28 FONT_S="${S}"
  29 FONT_SUFFIX="otf"
  30 FONT_CONF=( "${FILESDIR}"/63-${PN}.conf )
  31 RESTRICT="binchecks strip"
  32
  33 src_prepare() {
  34         mv source-*/OTF/*.otf . || die
  35 }
  36
  37 src_install() {
  38         font_src_install
  39         for d in source-sans-pro-${SANSV/\//-} source-serif-pro-${SERIFV} source-code-pro-${CODEV}; do
  40                 dohtml ${d}/*.html
  41         done
  42 }