mate-base/mate-session-manager/mate-session-manager-1.22.1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit mate
   7
   8 if [[ ${PV} != 9999 ]]; then
   9         KEYWORDS="~amd64 ~arm ~arm64 ~x86"
  10 fi
  11
  12 DESCRIPTION="MATE session manager"
  13 HOMEPAGE="https://mate-desktop.org/"
  14
  15 LICENSE="GPL-2 LGPL-2 FDL-1.1"
  16 SLOT="0"
  17 IUSE="debug elibc_FreeBSD elogind gnome-keyring ipv6 systemd +xtrans"
  18
  19 REQUIRED_USE="?? ( elogind systemd )"
  20
  21 # x11-misc/xdg-user-dirs{,-gtk} are needed to create the various XDG_*_DIRs, and
  22 # create .config/user-dirs.dirs which is read by glib to get G_USER_DIRECTORY_*
  23 # xdg-user-dirs-update is run during login (see 10-user-dirs-update-gnome below).
  24
  25 COMMON_DEPEND="
  26         >=dev-libs/dbus-glib-0.76
  27         >=dev-libs/glib-2.50:2
  28         dev-libs/libxslt
  29         sys-apps/dbus
  30         x11-libs/gdk-pixbuf:2
  31         >=x11-libs/gtk+-3.22:3
  32         x11-libs/libICE
  33         x11-libs/libSM
  34         x11-libs/libX11
  35         x11-libs/libXau
  36         x11-libs/libXext
  37         x11-libs/libXrender
  38         x11-libs/libXtst
  39         x11-libs/pango
  40         virtual/libintl
  41         elibc_FreeBSD? ( || ( dev-libs/libexecinfo >=sys-freebsd/freebsd-lib-10.0 ) )
  42         systemd? ( sys-apps/systemd )
  43         !systemd? (
  44                 elogind? ( sys-auth/elogind )
  45                 !elogind? ( >=sys-auth/consolekit-0.9.2 )
  46         )
  47         xtrans? ( x11-libs/xtrans )"
  48
  49 RDEPEND="${COMMON_DEPEND}
  50         x11-apps/xdpyinfo
  51         x11-misc/xdg-user-dirs
  52         x11-misc/xdg-user-dirs-gtk
  53         gnome-keyring? ( gnome-base/gnome-keyring )
  54         !<gnome-base/gdm-2.20.4"
  55
  56 DEPEND="${COMMON_DEPEND}
  57         >=dev-lang/perl-5
  58         dev-util/glib-utils
  59         >=dev-util/intltool-0.40
  60         >=sys-devel/gettext-0.10.40
  61         virtual/pkgconfig"
  62
  63 MATE_FORCE_AUTORECONF=true
  64
  65 src_configure() {
  66         mate_src_configure \
  67                 --docdir="${EPREFIX}/usr/share/doc/${PF}" \
  68                 $(use_with elogind) \
  69                 $(use_with systemd) \
  70                 $(use_with xtrans)  \
  71                 $(use_enable debug) \
  72                 $(use_enable ipv6)
  73 }
  74
  75 src_install() {
  76         mate_src_install
  77
  78         dodir /etc/X11/Sessions/
  79         exeinto /etc/X11/Sessions/
  80         doexe "${FILESDIR}"/MATE
  81
  82         dodir /usr/share/mate/applications/
  83         insinto /usr/share/mate/applications/
  84         doins "${FILESDIR}"/defaults.list
  85
  86         dodir /etc/X11/xinit/xinitrc.d/
  87         exeinto /etc/X11/xinit/xinitrc.d/
  88         doexe "${FILESDIR}"/15-xdg-data-mate
  89
  90         # This should be done in MATE too, see Gentoo bug #270852
  91         doexe "${FILESDIR}"/10-user-dirs-update-mate
  92 }