mail-client/trojita/trojita-9999.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 if [[ ${PV} = *9999* ]]; then
   7         EGIT_REPO_URI="https://anongit.kde.org/${PN}.git"
   8         inherit git-r3
   9 else
  10         SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz"
  11         KEYWORDS="~amd64 ~x86"
  12 fi
  13 inherit cmake-utils virtualx xdg
  14
  15 DESCRIPTION="A Qt IMAP e-mail client"
  16 HOMEPAGE="http://trojita.flaska.net/"
  17
  18 LICENSE="|| ( GPL-2 GPL-3 )"
  19 SLOT="0"
  20 IUSE="+crypt +dbus debug +password pim +spell test +zlib"
  21 RESTRICT="!test? ( test )"
  22
  23 REQUIRED_USE="password? ( dbus )"
  24
  25 BDEPEND="
  26         dev-qt/linguist-tools:5
  27         zlib? ( virtual/pkgconfig )
  28 "
  29 RDEPEND="
  30         dev-qt/qtcore:5
  31         dev-qt/qtgui:5
  32         dev-qt/qtnetwork:5[ssl]
  33         dev-qt/qtsql:5[sqlite]
  34         dev-qt/qtsvg:5
  35         dev-qt/qtwebkit:5
  36         dev-qt/qtwidgets:5
  37         crypt? (
  38                 >=app-crypt/gpgme-1.8.0[cxx,qt5]
  39                 dev-libs/mimetic
  40         )
  41         dbus? ( dev-qt/qtdbus:5 )
  42         password? ( dev-libs/qtkeychain[qt5(+)] )
  43         pim? ( kde-apps/akonadi-contacts:5 )
  44         spell? ( kde-frameworks/sonnet:5 )
  45         zlib? ( sys-libs/zlib )
  46 "
  47 DEPEND="${RDEPEND}
  48         test? ( dev-qt/qttest:5 )
  49 "
  50
  51 DOCS=( README LICENSE )
  52
  53 src_prepare() {
  54         cmake-utils_src_prepare
  55
  56         # the build system is taking a look at `git describe ... --dirty` and
  57         # gentoo's modifications to CMakeLists.txt break these
  58         sed -e "s/--dirty//" -i cmake/TrojitaVersion.cmake || die "Cannot fix the version check"
  59 }
  60
  61 src_configure() {
  62         local mycmakeargs=(
  63                 -DWITH_ABOOKADDRESSBOOK_PLUGIN=ON
  64                 -DWITH_CRYPTO_MESSAGES=$(usex crypt)
  65                 -DWITH_GPGMEPP=$(usex crypt)
  66                 -DWITH_MIMETIC=$(usex crypt)
  67                 -DWITH_DBUS=$(usex dbus)
  68                 -DWITH_QTKEYCHAIN_PLUGIN=$(usex password)
  69                 -DWITH_AKONADIADDRESSBOOK_PLUGIN=$(usex pim)
  70                 -DWITH_SONNET_PLUGIN=$(usex spell)
  71                 -DBUILD_TESTING=$(usex test)
  72                 -DWITH_ZLIB=$(usex zlib)
  73         )
  74
  75         cmake-utils_src_configure
  76 }
  77
  78 src_test() {
  79         virtx cmake-utils_src_test
  80 }