mail-client/roundcube/roundcube-1.4.3.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit webapp
   7
   8 MY_PN=${PN}mail
   9 MY_PV=${PV/_/-}
  10 MY_P=${MY_PN}-${MY_PV}
  11
  12 DESCRIPTION="A browser-based multilingual IMAP client with an application-like user interface"
  13 HOMEPAGE="https://roundcube.net"
  14 SRC_URI="https://github.com/${PN}/${MY_PN}/releases/download/${MY_PV}/${MY_P}-complete.tar.gz"
  15
  16 # roundcube is GPL-licensed, the rest of the licenses here are
  17 # for bundled PEAR components, googiespell and utf8.class.php
  18 LICENSE="GPL-3 BSD PHP-2.02 PHP-3 MIT public-domain"
  19 KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86"
  20
  21 IUSE="change-password enigma ldap mysql postgres sqlite ssl spell"
  22 REQUIRED_USE="|| ( mysql postgres sqlite )"
  23
  24 # this function only sets DEPEND so we need to include that in RDEPEND
  25 need_httpd_cgi
  26
  27 RDEPEND="
  28         ${DEPEND}
  29         >=dev-lang/php-5.4.0[filter,gd,iconv,json,ldap?,pdo,postgres?,session,sqlite?,ssl?,unicode,xml]
  30         virtual/httpd-php
  31         change-password? (
  32                 dev-lang/php[sockets]
  33         )
  34         enigma? (
  35                 app-crypt/gnupg
  36         )
  37         mysql? (
  38                 || (
  39                         dev-lang/php[mysql]
  40                         dev-lang/php[mysqli]
  41                 )
  42         )
  43         spell? ( dev-lang/php[curl,spell] )
  44 "
  45
  46 S="${WORKDIR}/${MY_P}"
  47
  48 src_install() {
  49         webapp_src_preinst
  50
  51         dodoc CHANGELOG INSTALL README.md UPGRADING
  52
  53         insinto "${MY_HTDOCSDIR}"
  54         doins -r [[:lower:]]* SQL
  55         doins .htaccess
  56
  57         webapp_serverowned "${MY_HTDOCSDIR}"/logs
  58         webapp_serverowned "${MY_HTDOCSDIR}"/temp
  59
  60         webapp_configfile "${MY_HTDOCSDIR}"/config/defaults.inc.php
  61         webapp_postupgrade_txt en "${FILESDIR}/POST-UPGRADE_complete.txt"
  62
  63         webapp_src_install
  64 }
  65
  66 pkg_postinst() {
  67         webapp_pkg_postinst
  68
  69         if [[ -n ${REPLACING_VERSIONS} ]]; then
  70                 elog "You can review the post-upgrade instructions at:"
  71                 elog "${EROOT%/}/usr/share/webapps/${PN}/${PV}/postupgrade-en.txt"
  72         fi
  73 }