kde-base/plasma-workspace/plasma-workspace-4.11.19.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 DECLARATIVE_REQUIRED="always"
   8 KDE_HANDBOOK="optional"
   9 KMNAME="kde-workspace"
  10 KMMODULE="plasma"
  11 PYTHON_COMPAT=( python2_7 )
  12 OPENGL_REQUIRED="always"
  13 inherit python-single-r1 kde4-meta
  14
  15 DESCRIPTION="Plasma: KDE desktop framework"
  16 KEYWORDS="amd64 ~arm ppc ppc64 x86 ~amd64-linux ~x86-linux"
  17 IUSE="debug gps json +kdepim python qalculate"
  18
  19 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
  20
  21 COMMONDEPEND="
  22         dev-libs/libdbusmenu-qt
  23         >=dev-qt/qtcore-4.8.4-r3:4
  24         !kde-misc/ktouchpadenabler
  25         $(add_kdebase_dep kactivities)
  26         $(add_kdebase_dep kephal)
  27         $(add_kdebase_dep ksysguard)
  28         $(add_kdebase_dep libkworkspace)
  29         $(add_kdebase_dep libplasmaclock 'kdepim?')
  30         $(add_kdebase_dep libplasmagenericshell)
  31         $(add_kdebase_dep libtaskmanager)
  32         x11-libs/libX11
  33         x11-libs/libXcomposite
  34         x11-libs/libXdamage
  35         x11-libs/libXext
  36         x11-libs/libXfixes
  37         x11-libs/libXi
  38         x11-libs/libXrender
  39         gps? ( >=sci-geosciences/gpsd-2.37 )
  40         json? ( dev-libs/qjson )
  41         kdepim? ( $(add_kdeapps_dep kdepimlibs) )
  42         python? (
  43                 ${PYTHON_DEPS}
  44                 >=dev-python/PyQt4-4.4.0[X,${PYTHON_USEDEP}]
  45                 $(add_kdebase_dep pykde4 "${PYTHON_USEDEP}")
  46         )
  47         qalculate? ( sci-libs/libqalculate )
  48 "
  49 DEPEND="${COMMONDEPEND}
  50         dev-libs/boost
  51         x11-proto/compositeproto
  52         x11-proto/damageproto
  53         x11-proto/fixesproto
  54         x11-proto/renderproto
  55 "
  56 RDEPEND="${COMMONDEPEND}
  57         $(add_kdeapps_dep plasma-runtime)
  58 "
  59
  60 KMEXTRA="
  61         appmenu/
  62         ktouchpadenabler/
  63         statusnotifierwatcher/
  64 "
  65 KMEXTRACTONLY="
  66         kcheckpass/
  67         krunner/dbus/org.freedesktop.ScreenSaver.xml
  68         krunner/dbus/org.kde.krunner.App.xml
  69         ksmserver/org.kde.KSMServerInterface.xml
  70         ksmserver/screenlocker/
  71         libs/kephal/
  72         libs/kworkspace/
  73         libs/taskmanager/
  74         libs/plasmagenericshell/
  75         libs/ksysguard/
  76         libs/kdm/kgreeterplugin.h
  77         ksysguard/
  78 "
  79
  80 pkg_setup() {
  81         if use python ; then
  82                 python-single-r1_pkg_setup
  83         fi
  84         kde4-meta_pkg_setup
  85 }
  86
  87 src_unpack() {
  88         if use handbook; then
  89                 KMEXTRA+=" doc/plasma-desktop"
  90         fi
  91
  92         kde4-meta_src_unpack
  93 }
  94
  95 src_configure() {
  96         local mycmakeargs=(
  97                 -DWITH_NepomukCore=OFF
  98                 -DWITH_Soprano=OFF
  99                 -DWITH_Xmms=OFF
 100                 $(cmake-utils_use_with gps libgps)
 101                 $(cmake-utils_use_with json QJSON)
 102                 $(cmake-utils_use_with kdepim Akonadi)
 103                 $(cmake-utils_use_with kdepim KdepimLibs)
 104                 $(cmake-utils_use_with python PythonLibrary)
 105                 $(cmake-utils_use_with qalculate)
 106         )
 107
 108         kde4-meta_src_configure
 109 }
 110
 111 src_install() {
 112         kde4-meta_src_install
 113
 114         if use python; then
 115                 python_optimize "${ED}"
 116         fi
 117 }