kde-apps/audiocd-kio/audiocd-kio-20.04.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 ECM_HANDBOOK="forceoptional"
   7 PVCUT=$(ver_cut 1-3)
   8 KFMIN=5.69.0
   9 QTMIN=5.12.3
  10 inherit ecm kde.org
  11
  12 DESCRIPTION="kioslave for accessing audio CDs"
  13
  14 LICENSE="GPL-2+ handbook? ( FDL-1.2 )"
  15 SLOT="5"
  16 KEYWORDS="~amd64 ~arm64 ~x86"
  17 IUSE="flac vorbis"
  18
  19 DEPEND="
  20         >=kde-frameworks/kcompletion-${KFMIN}:5
  21         >=kde-frameworks/kconfig-${KFMIN}:5
  22         >=kde-frameworks/kconfigwidgets-${KFMIN}:5
  23         >=kde-frameworks/kcoreaddons-${KFMIN}:5
  24         >=kde-frameworks/kcmutils-${KFMIN}:5
  25         >=kde-frameworks/ki18n-${KFMIN}:5
  26         >=kde-frameworks/kio-${KFMIN}:5
  27         >=kde-apps/libkcddb-${PVCUT}:5
  28         >=kde-apps/libkcompactdisc-${PVCUT}:5
  29         >=dev-qt/qtwidgets-${QTMIN}:5
  30         media-sound/cdparanoia
  31         flac? ( >=media-libs/flac-1.1.2 )
  32         vorbis? (
  33                 media-libs/libogg
  34                 media-libs/libvorbis
  35         )
  36 "
  37 RDEPEND="${DEPEND}"
  38
  39 PATCHES=( "${FILESDIR}/${PN}-19.04.0-handbook.patch" )
  40
  41 src_configure() {
  42         local mycmakeargs=(
  43                 $(cmake_use_find_package flac FLAC)
  44                 $(cmake_use_find_package vorbis OggVorbis)
  45         )
  46
  47         ecm_src_configure
  48 }