gnome-extra/cinnamon-desktop/cinnamon-desktop-3.6.2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 PYTHON_COMPAT=( python3_6 )
   6
   7 inherit autotools eutils gnome2 python-single-r1
   8
   9 DESCRIPTION="A collection of libraries and utilites used by Cinnamon"
  10 HOMEPAGE="http://developer.linuxmint.com/projects/cinnamon-projects.html"
  11 SRC_URI="https://github.com/linuxmint/cinnamon-desktop/archive/${PV}.tar.gz -> ${P}.tar.gz"
  12
  13 LICENSE="GPL-2+ FDL-1.1+ LGPL-2+"
  14 SLOT="0/4" # subslot = libcinnamon-desktop soname version
  15 KEYWORDS="amd64 x86"
  16 IUSE="+introspection systemd"
  17 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  18
  19 COMMON_DEPEND="${PYTHON_DEPS}
  20         >=dev-libs/glib-2.37.3:2[dbus]
  21         media-sound/pulseaudio[glib]
  22         >=x11-libs/gdk-pixbuf-2.22:2[introspection?]
  23         >=x11-libs/gtk+-3.3.16:3[introspection?]
  24         >=x11-libs/libXext-1.1
  25         >=x11-libs/libXrandr-1.3
  26         x11-libs/cairo:=[X]
  27         x11-libs/libX11
  28         x11-libs/libxkbfile
  29         x11-misc/xkeyboard-config
  30         >=gnome-base/gsettings-desktop-schemas-3.5.91
  31         introspection? ( >=dev-libs/gobject-introspection-0.9.7:= )
  32         sys-apps/accountsservice
  33 "
  34 RDEPEND="${COMMON_DEPEND}
  35         dev-python/pygobject:3[${PYTHON_USEDEP}]
  36 "
  37 DEPEND="${COMMON_DEPEND}
  38         >=dev-util/gtk-doc-am-1.4
  39         >=dev-util/intltool-0.40.6
  40         gnome-base/gnome-common
  41         x11-base/xorg-proto
  42         virtual/pkgconfig
  43 "
  44
  45 pkg_setup() {
  46         python_setup
  47 }
  48
  49 src_prepare() {
  50         eautoreconf
  51         gnome2_src_prepare
  52 }
  53
  54 src_configure() {
  55         gnome2_src_configure \
  56                 --disable-static \
  57                 $(use_enable introspection)
  58 }
  59
  60 src_install() {
  61         gnome2_src_install
  62
  63         # set sane default gschema values for systemd users
  64         if use systemd; then
  65                 insinto /usr/share/glib-2.0/schemas/
  66                 newins "${FILESDIR}"/${PN}-2.6.4.systemd.gschema.override ${PN}.systemd.gschema.override
  67         fi
  68 }