gnome-base/gnome-desktop/gnome-desktop-3.34.5.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 inherit gnome.org gnome2-utils meson virtualx xdg
   6
   7 DESCRIPTION="Library with common API for various GNOME modules"
   8 HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-desktop/"
   9
  10 LICENSE="GPL-2+ LGPL-2+ FDL-1.1+"
  11 SLOT="3/18" # subslot = libgnome-desktop-3 soname version
  12 IUSE="debug gtk-doc +introspection seccomp systemd udev"
  13 KEYWORDS="~alpha amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
  14
  15 # cairo[X] needed for gnome-bg
  16 COMMON_DEPEND="
  17         >=x11-libs/gdk-pixbuf-2.36.5:2[introspection?]
  18         >=x11-libs/gtk+-3.3.6:3[X,introspection?]
  19         >=dev-libs/glib-2.53.0:2
  20         >=gnome-base/gsettings-desktop-schemas-3.27.0[introspection?]
  21         x11-misc/xkeyboard-config
  22         app-text/iso-codes
  23         x11-libs/libX11
  24         systemd? ( sys-apps/systemd:= )
  25         udev? (
  26                 sys-apps/hwids
  27                 virtual/libudev:= )
  28         seccomp? ( sys-libs/libseccomp )
  29
  30         x11-libs/cairo:=[X]
  31         introspection? ( >=dev-libs/gobject-introspection-1.54:= )
  32 "
  33 DEPEND="${COMMON_DEPEND}
  34         media-libs/fontconfig
  35 "
  36 RDEPEND="${COMMON_DEPEND}
  37         seccomp? ( sys-apps/bubblewrap )
  38 "
  39 BDEPEND="
  40         app-text/docbook-xml-dtd:4.1.2
  41         dev-util/gdbus-codegen
  42         gtk-doc? ( >=dev-util/gtk-doc-1.14 )
  43         dev-util/itstool
  44         >=sys-devel/gettext-0.19.8
  45         x11-base/xorg-proto
  46         virtual/pkgconfig
  47 "
  48 # Includes X11/Xatom.h in libgnome-desktop/gnome-bg.c which comes from xorg-proto
  49
  50 PATCHES=(
  51         "${FILESDIR}"/3.32.2-optional-introspection.patch # add introspection meson option
  52 )
  53
  54 src_prepare() {
  55         # Don't build manual test programs that will never get run
  56         sed -i -e "/'test-.*'/d" libgnome-desktop/meson.build || die
  57         xdg_src_prepare
  58 }
  59
  60 src_configure() {
  61         local emesonargs=(
  62                 -Dgnome_distributor=Gentoo
  63                 -Ddate_in_gnome_version=true
  64                 -Ddesktop_docs=true
  65                 $(meson_use debug debug_tools)
  66                 $(meson_use introspection)
  67                 $(meson_feature udev)
  68                 $(meson_feature systemd)
  69                 $(meson_use gtk-doc gtk_doc)
  70                 -Dinstalled_tests=false
  71         )
  72         meson_src_configure
  73 }
  74
  75 src_test() {
  76         virtx meson_src_test
  77 }