games-strategy/widelands/widelands-0.20-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{6,7,8} )
   7
   8 inherit desktop cmake python-any-r1
   9
  10 MY_PV="build$(ver_cut 2-)"
  11 MY_P="${PN}-${MY_PV/_/-}"
  12
  13 DESCRIPTION="A game similar to Settlers 2"
  14 HOMEPAGE="http://www.widelands.org/"
  15 SRC_URI="https://launchpad.net/widelands/build$(ver_cut 2)/${MY_PV/_/-}/+download/${MY_P}.tar.bz2"
  16
  17 LICENSE="GPL-2+"
  18 SLOT="0"
  19 KEYWORDS="~amd64 ~x86"
  20 IUSE=""
  21
  22 RDEPEND="
  23         >=dev-libs/boost-1.48:=
  24         dev-libs/icu:=
  25         media-libs/glew:0=
  26         media-libs/libglvnd
  27         media-libs/libpng:0=
  28         media-libs/libsdl2[video]
  29         media-libs/sdl2-image[jpeg,png]
  30         media-libs/sdl2-mixer[vorbis]
  31         media-libs/sdl2-ttf
  32         sys-libs/zlib:=[minizip]"
  33 DEPEND="${RDEPEND}
  34         ${PYTHON_DEPS}
  35         dev-lang/lua:0
  36 "
  37 BDEPEND="
  38         sys-devel/gettext
  39 "
  40
  41 CMAKE_BUILD_TYPE="Release"
  42
  43 S="${WORKDIR}/${MY_P}"
  44
  45 PATCHES=(
  46         "${FILESDIR}/${PN}-0.20_rc1-cxxflags.patch"
  47         "${FILESDIR}/${PN}-0.20-glvnd.patch"
  48 )
  49
  50 src_prepare() {
  51         cmake_src_prepare
  52
  53         sed -i -e 's:__ppc__:__PPC__:' src/map_io/s2map.cc || die
  54 }
  55
  56 src_configure() {
  57         local mycmakeargs=(
  58                 -DOPTION_BUILD_WEBSITE_TOOLS=OFF
  59
  60                 # Upstream's cmake files are totally fscked up...
  61                 -DCMAKE_INSTALL_PREFIX="${EPREFIX}"/usr/share/doc/${PF}
  62                 # Game is NOT happy being moved from /usr/share/games
  63                 -DWL_INSTALL_DATADIR="${EPREFIX}"/usr/share/games/${PN}
  64         )
  65         cmake_src_configure
  66 }
  67
  68 src_install() {
  69         cmake_src_install
  70
  71         # move game binary to correct location
  72         dodir /usr/bin
  73         mv "${ED}"/usr/share/doc/${PF}/${PN} "${ED}"/usr/bin || die
  74
  75         newicon data/images/logos/wl-ico-128.png ${PN}.png
  76         make_desktop_entry ${PN} ${PN^}
  77 }