games-strategy/warzone2100/warzone2100-3.2.3.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit autotools toolchain-funcs eutils versionator gnome2-utils
   6
   7 MY_PV=$(get_version_component_range -2)
   8 VIDEOS_PV=2.2
   9 VIDEOS_P=${PN}-videos-${VIDEOS_PV}.wz
  10 DESCRIPTION="3D real-time strategy game"
  11 HOMEPAGE="http://wz2100.net/"
  12 SRC_URI="mirror://sourceforge/warzone2100/${P}.tar.xz
  13         videos? ( mirror://sourceforge/warzone2100/warzone2100/Videos/${VIDEOS_PV}/high-quality-en/sequences.wz -> ${VIDEOS_P} )"
  14
  15 SRC_URI+=" https://github.com/Warzone2100/warzone2100/commit/ef37bca38289f4f79c6533acd93ed326858a3f68.patch -> ${PN}-3.2.3-qt_compile_fix.patch"
  16
  17 LICENSE="GPL-2+ CC-BY-SA-3.0 public-domain"
  18 SLOT="0"
  19 KEYWORDS="~amd64 ~x86"
  20 # upstream requested debug support
  21 IUSE="debug nls sdl videos"
  22
  23 # TODO: unbundle miniupnpc and quesoglc
  24 # quesoglc-0.7.2 is buggy: http://developer.wz2100.net/ticket/2828
  25 CDEPEND="
  26         >=dev-games/physfs-2[zip]
  27         dev-libs/openssl:0=
  28         dev-qt/qtcore:5
  29         dev-qt/qtgui:5
  30         dev-qt/qtscript:5
  31         dev-qt/qtwidgets:5
  32         media-libs/freetype:2
  33         media-libs/glew:=
  34         media-libs/harfbuzz
  35         media-libs/libogg
  36         media-libs/libpng:0
  37         media-libs/libtheora
  38         media-libs/libvorbis
  39         media-libs/openal
  40         sys-libs/zlib
  41         virtual/glu
  42         virtual/opengl
  43         x11-libs/libX11
  44         x11-libs/libXrandr
  45         nls? ( virtual/libintl )
  46         !sdl? (
  47                 dev-qt/qtopengl:5
  48                 dev-qt/qtx11extras:5
  49         )
  50         sdl? ( media-libs/libsdl2[opengl,video,X] )
  51 "
  52 DEPEND="
  53         ${CDEPEND}
  54         app-arch/zip
  55         dev-libs/fribidi
  56         media-libs/fontconfig
  57         virtual/pkgconfig
  58         nls? ( sys-devel/gettext )
  59 "
  60 RDEPEND="
  61         ${CDEPEND}
  62         media-fonts/dejavu
  63 "
  64
  65 src_prepare() {
  66         default
  67
  68         # https://developer.wz2100.net/ticket/4580
  69         eapply "${DISTDIR}/${P}-qt_compile_fix.patch"
  70
  71         sed -i -e 's/#top_builddir/top_builddir/' po/Makevars || die
  72         sed '/appdata\.xml/d' -i icons/Makefile.am || die
  73         eautoreconf
  74 }
  75
  76 src_configure() {
  77         local myeconfargs=(
  78                 --docdir=/usr/share/doc/${PF}
  79                 --localedir=/usr/share/locale
  80                 --with-distributor="Gentoo ${PF}"
  81                 --with-icondir=/usr/share/icons/hicolor/128x128/apps
  82                 --with-applicationdir=/usr/share/applications
  83                 $(use_enable debug debug relaxed)
  84                 $(use_enable nls)
  85                 --with-backend=$(usex sdl "sdl" "qt")
  86         )
  87         econf "${myeconfargs[@]}"
  88 }
  89
  90 src_compile() {
  91         emake AR="$(tc-getAR)"
  92 }
  93
  94 src_install() {
  95         default
  96         rm -f "${D}"/usr/share/doc/${PF}/COPYING*
  97         if use videos ; then
  98                 insinto /usr/share/${PN}
  99                 newins "${DISTDIR}"/${VIDEOS_P} sequences.wz
 100         fi
 101         doman doc/warzone2100.6
 102         dodoc doc/quickstartguide.pdf
 103 }
 104
 105 pkg_preinst() {
 106         gnome2_icon_savelist
 107 }
 108
 109 pkg_postinst() {
 110         gnome2_icon_cache_update
 111 }
 112
 113 pkg_postrm() {
 114         gnome2_icon_cache_update
 115 }