games-strategy/netpanzer/netpanzer-0.8.2.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5 inherit eutils games
   6
   7 DATAVERSION="0.8"
   8 DESCRIPTION="Fast-action multiplayer strategic network game"
   9 HOMEPAGE="http://www.netpanzer.info/"
  10 SRC_URI="mirror://sourceforge/netpanzer.berlios/${P}.tar.bz2
  11         mirror://sourceforge/netpanzer.berlios/${PN}-data-${DATAVERSION}.tar.bz2"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="~x86"
  16 IUSE="dedicated"
  17
  18 RDEPEND="dedicated? ( app-misc/screen )
  19         media-libs/libsdl[sound,video]
  20         media-libs/sdl-mixer
  21         media-libs/sdl-image
  22         dev-games/physfs"
  23 DEPEND="${RDEPEND}
  24         dev-util/ftjam"
  25
  26 src_prepare() {
  27         epatch \
  28                 "${FILESDIR}"/${P}-gcc43.patch \
  29                 "${FILESDIR}"/${P}-gcc47.patch
  30 }
  31
  32 src_configure() {
  33         egamesconf
  34         cd "${WORKDIR}"/${PN}-data-${DATAVERSION} \
  35                 && egamesconf
  36 }
  37
  38 src_compile() {
  39         AR="${AR} cru" jam -q || die
  40
  41         cd "${WORKDIR}"/${PN}-data-${DATAVERSION}
  42         jam -q || die
  43 }
  44
  45 src_install() {
  46         jam -sDESTDIR="${D}" -sappdocdir=/usr/share/doc/${PF} install || die
  47
  48         cd "${WORKDIR}"/${PN}-data-${DATAVERSION}
  49         jam -sDESTDIR="${D}" -sappdocdir=/usr/share/doc/${PF} install || die
  50
  51         if use dedicated ; then
  52                 newinitd "${FILESDIR}"/${PN}.rc ${PN}
  53                 sed -i \
  54                         -e "s:GAMES_USER_DED:${GAMES_USER_DED}:" \
  55                         -e "s:GENTOO_DIR:${GAMES_BINDIR}:" \
  56                         "${D}"/etc/init.d/${PN} || die
  57
  58                 insinto /etc
  59                 doins "${FILESDIR}"/${PN}-ded.ini
  60                 dogamesbin "${FILESDIR}"/${PN}-ded
  61                 sed -i \
  62                         -e "s:GENTOO_DIR:${GAMES_BINDIR}:" \
  63                         "${D}/${GAMES_BINDIR}"/${PN}-ded || die
  64         fi
  65
  66         rm -rf "${D}/${GAMES_DATADIR}"/{applications,pixmaps}
  67         doicon "${S}"/${PN}.png
  68         make_desktop_entry ${PN} NetPanzer
  69         prepgamesdirs
  70 }