dev-util/ninja/ninja-9999.ebuild

   1 # Copyright 2012-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python{2_7,3_6,3_7} )
   7
   8 inherit bash-completion-r1 elisp-common python-any-r1 toolchain-funcs
   9
  10 if [[ ${PV} == 9999 ]]; then
  11         inherit git-r3
  12         EGIT_REPO_URI="https://github.com/ninja-build/ninja.git"
  13 else
  14         KITWARE_VERSION="1.9.0.g99df1.kitware.dyndep-1.jobserver-1"
  15         MY_P="ninja-${KITWARE_VERSION}"
  16         S="${WORKDIR}/${MY_P}"
  17         SRC_URI="https://github.com/Kitware/ninja/archive/v${KITWARE_VERSION}.tar.gz -> ${MY_P}.tar.gz"
  18         KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sh ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris"
  19 fi
  20
  21 DESCRIPTION="A small build system similar to make"
  22 HOMEPAGE="https://ninja-build.org/"
  23
  24 LICENSE="Apache-2.0"
  25 SLOT="0"
  26
  27 IUSE="doc emacs test vim-syntax"
  28 RESTRICT="!test? ( test )"
  29
  30 BDEPEND="
  31         ${PYTHON_DEPS}
  32         dev-util/re2c
  33         doc? (
  34                 app-text/asciidoc
  35                 app-doc/doxygen
  36                 dev-libs/libxslt
  37         )
  38         test? ( dev-cpp/gtest )
  39 "
  40 RDEPEND="
  41         emacs? ( >=app-editors/emacs-23.1:* )
  42         vim-syntax? (
  43                 || (
  44                         app-editors/vim
  45                         app-editors/gvim
  46                 )
  47         )
  48 "
  49
  50 run_for_build() {
  51         if tc-is-cross-compiler; then
  52                 local -x AR=$(tc-getBUILD_AR)
  53                 local -x CXX=$(tc-getBUILD_CXX)
  54                 local -x CFLAGS=
  55                 local -x CXXFLAGS=${BUILD_CXXFLAGS}
  56                 local -x LDFLAGS=${BUILD_LDFLAGS}
  57         fi
  58         echo "$@" >&2
  59         "$@"
  60 }
  61
  62 src_compile() {
  63         tc-export AR CXX
  64
  65         # configure.py uses CFLAGS instead of CXXFLAGS
  66         export CFLAGS=${CXXFLAGS}
  67
  68         run_for_build ${EPYTHON} configure.py --bootstrap --verbose || die
  69
  70         if tc-is-cross-compiler; then
  71                 mv ninja ninja-build || die
  72                 ${EPYTHON} configure.py || die
  73                 ./ninja-build -v ninja || die
  74         else
  75                 ln ninja ninja-build || die
  76         fi
  77
  78         if use doc; then
  79                 ./ninja-build -v doxygen manual || die
  80         fi
  81
  82         if use emacs; then
  83                 elisp-compile misc/ninja-mode.el || die
  84         fi
  85 }
  86
  87 src_test() {
  88         if ! tc-is-cross-compiler; then
  89                 # Bug 485772
  90                 ulimit -n 2048
  91                 ./ninja -v ninja_test || die
  92                 ./ninja_test || die
  93         fi
  94 }
  95
  96 src_install() {
  97         dodoc README HACKING.md
  98         if use doc; then
  99                 docinto html
 100                 dodoc -r doc/doxygen/html/.
 101                 dodoc doc/manual.html
 102         fi
 103         dobin ninja
 104
 105         newbashcomp misc/bash-completion "${PN}"
 106
 107         if use vim-syntax; then
 108                 insinto /usr/share/vim/vimfiles/syntax/
 109                 doins misc/ninja.vim
 110
 111                 echo 'au BufNewFile,BufRead *.ninja set ft=ninja' > "${T}/ninja.vim"
 112                 insinto /usr/share/vim/vimfiles/ftdetect
 113                 doins "${T}/ninja.vim"
 114         fi
 115
 116         insinto /usr/share/zsh/site-functions
 117         newins misc/zsh-completion _ninja
 118
 119         if use emacs; then
 120                 cd misc || die
 121                 elisp-install ninja ninja-mode.el* || die
 122         fi
 123 }
 124
 125 pkg_postinst() {
 126         use emacs && elisp-site-regen
 127 }
 128
 129 pkg_postrm() {
 130         use emacs && elisp-site-regen
 131 }