dev-util/cunit/cunit-2.1_p3.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 inherit autotools flag-o-matic multilib-minimal toolchain-funcs
   6
   7 MY_PN="CUnit"
   8 MY_PV="${PV/_p*}-3"
   9 MY_P="${MY_PN}-${MY_PV}"
  10
  11 DESCRIPTION="C Unit Test Framework"
  12 HOMEPAGE="http://cunit.sourceforge.net"
  13 SRC_URI="mirror://sourceforge/cunit/${MY_P}.tar.bz2"
  14
  15 LICENSE="LGPL-2"
  16 SLOT="0"
  17 KEYWORDS="~alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 ~riscv s390 ~sh sparc x86 ~amd64-linux ~x86-linux ~ppc-macos"
  18 IUSE="ncurses static-libs"
  19
  20 RDEPEND="ncurses? ( >=sys-libs/ncurses-5.9-r3:0=[${MULTILIB_USEDEP}] )"
  21 DEPEND="${RDEPEND}"
  22 BDEPEND=""
  23
  24 S="${WORKDIR}/${MY_P}"
  25
  26 src_prepare() {
  27         default
  28
  29         sed -e "/^docdir/d" -i doc/Makefile.am || die
  30         sed -e '/^dochdrdir/{s:$(prefix)/doc/@PACKAGE@:$(docdir):}' \
  31                 -i doc/headers/Makefile.am || die
  32         sed -e "s/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/" -i configure.in || die
  33
  34         mv configure.{in,ac} || die
  35         eautoreconf
  36
  37         append-cppflags -D_BSD_SOURCE
  38
  39         # unable to find headers otherwise
  40         multilib_copy_sources
  41 }
  42
  43 multilib_src_configure() {
  44         local LIBS=${LIBS}
  45         append-libs $($(tc-getPKG_CONFIG) --libs ncurses)
  46
  47         econf \
  48                 --docdir="${EPREFIX}"/usr/share/doc/${PF} \
  49                 $(use_enable static-libs static) \
  50                 --disable-debug \
  51                 $(use_enable ncurses curses)
  52 }
  53
  54 multilib_src_install_all() {
  55         einstalldocs
  56         find "${D}" -name '*.la' -type f -delete || die
  57 }