dev-ruby/rubyzip/rubyzip-2.2.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 USE_RUBY="ruby24 ruby25 ruby26 ruby27"
   7
   8 RUBY_FAKEGEM_RECIPE_DOC="none"
   9 RUBY_FAKEGEM_EXTRADOC="Changelog.md README.md TODO"
  10
  11 RUBY_FAKEGEM_GEMSPEC="rubyzip.gemspec"
  12
  13 inherit ruby-fakegem
  14
  15 DESCRIPTION="A ruby library for reading and writing zip files"
  16 HOMEPAGE="https://github.com/rubyzip/rubyzip"
  17 # Tests are not included in the gem.
  18 SRC_URI="https://github.com/rubyzip/rubyzip/archive/v${PV}.tar.gz -> ${P}-git.tgz"
  19
  20 LICENSE="Ruby"
  21 SLOT="$(ver_cut 1)"
  22 KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86"
  23 IUSE=""
  24
  25 RDEPEND=""
  26 DEPEND="${DEPEND} test? ( app-arch/zip )"
  27
  28 ruby_add_bdepend "test? ( dev-ruby/minitest:5 )"
  29
  30 all_ruby_install() {
  31         all_fakegem_install
  32
  33         docinto examples
  34         dodoc samples/*
  35 }
  36
  37 all_ruby_prepare() {
  38         # Avoid dependencies on simplecov and coveralls
  39         sed -i -e '/simplecov/ s:^:#:' test/test_helper.rb || die
  40
  41         # Avoid dependency on bundler
  42         sed -i -e '/bundler/ s:^:#:' Rakefile || die
  43
  44         # Fix hardcoded path to /tmp
  45         sed -i -e 's:/tmp/:'${T}'/:g' test/entry_test.rb || die
  46
  47         # Add missing requires
  48         sed -i -e '1irequire "forwardable"; require "pathname"' test/input_stream_test.rb || die
  49 }