dev-ruby/rubygems/rubygems-3.1.2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 USE_RUBY="ruby24 ruby25 ruby26 ruby27"
   7
   8 inherit ruby-ng prefix
   9
  10 DESCRIPTION="Centralized Ruby extension management system"
  11 HOMEPAGE="https://rubygems.org/"
  12 LICENSE="GPL-2 || ( Ruby MIT )"
  13
  14 SRC_URI="https://rubygems.org/rubygems/${P}.tgz"
  15
  16 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  17 SLOT="0"
  18 IUSE="server test"
  19 RESTRICT="!test? ( test )"
  20
  21 PDEPEND="server? ( =dev-ruby/builder-3* )"
  22
  23 ruby_add_depend "virtual/ruby-ssl"
  24
  25 ruby_add_bdepend "
  26         test? (
  27                 dev-ruby/json
  28                 dev-ruby/minitest:5
  29                 dev-ruby/rake
  30                 dev-ruby/rdoc
  31         )"
  32
  33 all_ruby_prepare() {
  34
  35         mkdir -p lib/rubygems/defaults || die
  36         cp "${FILESDIR}/gentoo-defaults-4.rb" lib/rubygems/defaults/operating_system.rb || die
  37
  38         eprefixify lib/rubygems/defaults/operating_system.rb
  39
  40         # Disable broken tests when changing default values:
  41         sed -i -e '/test_default_path/,/^  end/ s:^:#:' test/rubygems/test_gem.rb || die
  42         # Avoid test that won't work as json is also installed as plain ruby code
  43         sed -i -e '/test_realworld_default_gem/askip "gentoo"' test/rubygems/test_require.rb || die
  44
  45         # Update manifest after changing files to avoid a test failure
  46         if use test; then
  47                 rake update_manifest || die
  48         fi
  49 }
  50
  51 each_ruby_compile() {
  52         # Not really a build but...
  53         sed -i -e 's:#!.*:#!'"${RUBY}"':' bin/gem
  54 }
  55
  56 each_ruby_test() {
  57         # Unset RUBYOPT to avoid interferences, bug #158455 et. al.
  58         #unset RUBYOPT
  59
  60         if [[ "${EUID}" -ne "0" ]]; then
  61                 RUBYLIB="$(pwd)/lib${RUBYLIB+:${RUBYLIB}}" ${RUBY} --disable-gems -I.:lib:test:bundler/lib \
  62                         -e 'require "rubygems"; gem "minitest", "~>5.0"; Dir["test/**/test_*.rb"].each { |tu| require tu }' || die "tests failed"
  63         else
  64                 ewarn "The userpriv feature must be enabled to run tests, bug 408951."
  65                 eerror "Testsuite will not be run."
  66         fi
  67 }
  68
  69 each_ruby_install() {
  70         # Unset RUBYOPT to avoid interferences, bug #158455 et. al.
  71         unset RUBYOPT
  72         export RUBYLIB="$(pwd)/lib${RUBYLIB+:${RUBYLIB}}"
  73
  74         pushd lib &>/dev/null
  75         doruby -r *
  76         popd &>/dev/null
  77
  78         local sld=$(ruby_rbconfig_value 'sitelibdir')
  79         insinto "${sld#${EPREFIX}}"  # bug #320813
  80         newins "${FILESDIR}/auto_gem.rb.ruby19" auto_gem.rb
  81
  82         newbin bin/gem $(basename ${RUBY} | sed -e 's:ruby:gem:')
  83 }
  84
  85 all_ruby_install() {
  86         dodoc History.txt README.md
  87
  88         if use server; then
  89                 newinitd "${FILESDIR}/init.d-gem_server2" gem_server
  90                 newconfd "${FILESDIR}/conf.d-gem_server" gem_server
  91         fi
  92 }
  93
  94 pkg_postinst() {
  95         if [[ ! -n $(readlink "${ROOT}"/usr/bin/gem) ]] ; then
  96                 eselect ruby set $(eselect --brief --colour=no ruby show | head -n1)
  97         fi
  98
  99         ewarn
 100         ewarn "To switch between available Ruby profiles, execute as root:"
 101         ewarn "\teselect ruby set ruby(25|26|...)"
 102         ewarn
 103 }