dev-ruby/rspec-expectations/rspec-expectations-3.9.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 USE_RUBY="ruby24 ruby25 ruby26 ruby27"
   6
   7 RUBY_FAKEGEM_RECIPE_TEST="rspec3"
   8
   9 RUBY_FAKEGEM_RECIPE_DOC="none"
  10 RUBY_FAKEGEM_EXTRADOC="Changelog.md README.md"
  11
  12 RUBY_FAKEGEM_GEMSPEC="${PN}.gemspec"
  13
  14 inherit ruby-fakegem
  15
  16 DESCRIPTION="A Behaviour Driven Development (BDD) framework for Ruby"
  17 HOMEPAGE="https://github.com/rspec/rspec-expectations"
  18 SRC_URI="https://github.com/rspec/${PN}/archive/v${PV}.tar.gz -> ${P}-git.tgz"
  19
  20 LICENSE="MIT"
  21 SLOT="3"
  22 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  23 IUSE=""
  24
  25 SUBVERSION="$(ver_cut 1-2)"
  26
  27 ruby_add_rdepend ">=dev-ruby/diff-lcs-1.2.0 <dev-ruby/diff-lcs-2
  28         =dev-ruby/rspec-support-${SUBVERSION}*"
  29
  30 ruby_add_bdepend "test? (
  31                 >=dev-ruby/rspec-mocks-3.2.0:3
  32                 >=dev-ruby/rspec-support-3.5.0:3
  33         )"
  34
  35 all_ruby_prepare() {
  36         # Don't set up bundler: it doesn't understand our setup.
  37         sed -i -e '/[Bb]undler/d' Rakefile || die
  38
  39         # Remove the Gemfile to avoid running through 'bundle exec'
  40         rm -f Gemfile || die
  41
  42         # fix up the gemspecs
  43         sed -i \
  44                 -e '/git ls/d' \
  45                 -e '/add_development_dependency/d' \
  46                 "${RUBY_FAKEGEM_GEMSPEC}" || die
  47 }