dev-ruby/racc/racc-1.4.14.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 USE_RUBY="ruby23 ruby24 ruby25 ruby26"
   7
   8 RUBY_FAKEGEM_RECIPE_DOC="rdoc"
   9 RUBY_FAKEGEM_TASK_DOC="docs"
  10 RUBY_FAKEGEM_EXTRADOC="README.rdoc README.ja.rdoc TODO ChangeLog"
  11
  12 inherit multilib ruby-fakegem
  13
  14 DESCRIPTION="A LALR(1) parser generator for Ruby"
  15 HOMEPAGE="https://github.com/tenderlove/racc"
  16
  17 LICENSE="LGPL-2.1"
  18 SLOT="0"
  19
  20 KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~mips ppc ppc64 s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  21 IUSE="doc test"
  22
  23 ruby_add_bdepend "dev-ruby/rake
  24         test? ( >=dev-ruby/minitest-4.0:0 )"
  25
  26 all_ruby_prepare() {
  27         sed -i -e 's|/tmp/out|${TMPDIR:-/tmp}/out|' test/helper.rb || die "tests fix failed"
  28
  29         # Avoid depending on rake-compiler since we don't use it to compile
  30         # the extension.
  31         sed -i -e '/rake-compiler/ s:^:#:' -e '/extensiontask/ s:^:#:' Rakefile
  32         sed -i -e '/ExtensionTask/,/^  end/ s:^:#:' Rakefile
  33
  34         # Avoid isolation since dependencies are not properly declared.
  35         sed -i -e 's/, :isolate//' Rakefile || die
  36
  37         # Use a version of the minitest gem that works consistently accross
  38         # all ruby versions.
  39         sed -i -e '2i gem "minitest", "~>4.0"' test/helper.rb || die
  40 }
  41
  42 each_ruby_prepare() {
  43         ${RUBY} -Cext/racc extconf.rb || die
  44 }
  45
  46 each_ruby_compile() {
  47         emake V=1 -Cext/racc
  48         # Copy over the file here so that we don't have to do
  49         # special ruby install for JRuby and the other
  50                 # implementations.
  51                 cp -l ext/racc/cparse$(get_modname) lib/racc/cparse$(get_modname) || die
  52 }
  53
  54 each_ruby_test() {
  55         ${RUBY} -Ilib:. -e "Dir['test/test_*.rb'].each{|f| require f}" || die
  56 }
  57
  58 all_ruby_install() {
  59         all_fakegem_install
  60
  61         dodoc -r rdoc
  62
  63         docinto examples
  64         dodoc -r sample
  65 }