dev-qt/qtdeclarative/qtdeclarative-5.13.2.ebuild

   1 # Copyright 2009-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 PYTHON_COMPAT=( python2_7 python3_{6,7} )
   6 inherit python-any-r1 qt5-build
   7
   8 DESCRIPTION="The QML and Quick modules for the Qt5 framework"
   9
  10 if [[ ${QT5_BUILD_TYPE} == release ]]; then
  11         KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86"
  12 fi
  13
  14 IUSE="gles2 +jit localstorage +widgets"
  15
  16 BDEPEND="${PYTHON_DEPS}"
  17 # qtgui[gles2=] is needed because of bug 504322
  18 DEPEND="
  19         ~dev-qt/qtcore-${PV}
  20         ~dev-qt/qtgui-${PV}[gles2=]
  21         ~dev-qt/qtnetwork-${PV}
  22         ~dev-qt/qttest-${PV}
  23         localstorage? ( ~dev-qt/qtsql-${PV} )
  24         widgets? ( ~dev-qt/qtwidgets-${PV}[gles2=] )
  25 "
  26 RDEPEND="${DEPEND}
  27         !<dev-qt/qtquickcontrols-5.7:5
  28 "
  29
  30 src_prepare() {
  31         use jit || PATCHES+=("${FILESDIR}/${PN}-5.4.2-disable-jit.patch")
  32
  33         qt_use_disable_mod localstorage sql \
  34                 src/imports/imports.pro
  35
  36         qt_use_disable_mod widgets widgets \
  37                 src/src.pro \
  38                 src/qmltest/qmltest.pro \
  39                 tests/auto/auto.pro \
  40                 tools/tools.pro \
  41                 tools/qmlscene/qmlscene.pro \
  42                 tools/qml/qml.pro
  43
  44         qt5-build_src_prepare
  45 }
  46
  47 src_configure() {
  48         local myqmakeargs=(
  49                 --
  50                 -qml-debug
  51         )
  52         qt5-build_src_configure
  53 }