dev-qt/designer/designer-5.14.2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 QT5_MODULE="qttools"
   6 inherit desktop qt5-build xdg-utils
   7
   8 DESCRIPTION="WYSIWYG tool for designing and building graphical user interfaces with QtWidgets"
   9
  10 if [[ ${QT5_BUILD_TYPE} == release ]]; then
  11         KEYWORDS="amd64 arm arm64 ~hppa ~ppc ppc64 x86"
  12 fi
  13
  14 IUSE="declarative webkit"
  15
  16 DEPEND="
  17         ~dev-qt/qtcore-${PV}:5=
  18         ~dev-qt/qtgui-${PV}:5=
  19         ~dev-qt/qtnetwork-${PV}
  20         ~dev-qt/qtprintsupport-${PV}
  21         ~dev-qt/qtwidgets-${PV}
  22         ~dev-qt/qtxml-${PV}
  23         declarative? ( ~dev-qt/qtdeclarative-${PV}[widgets] )
  24         webkit? ( >=dev-qt/qtwebkit-5.9.1:5 )
  25 "
  26 RDEPEND="${DEPEND}"
  27
  28 QT5_TARGET_SUBDIRS=(
  29         src/designer
  30 )
  31
  32 src_prepare() {
  33         qt_use_disable_mod declarative quickwidgets \
  34                 src/designer/src/plugins/plugins.pro
  35
  36         qt_use_disable_mod webkit webkitwidgets \
  37                 src/designer/src/plugins/plugins.pro
  38
  39         qt5-build_src_prepare
  40 }
  41
  42 src_install() {
  43         qt5-build_src_install
  44
  45         doicon -s 128 src/designer/src/designer/images/designer.png
  46         make_desktop_entry "${QT5_BINDIR}"/designer 'Qt 5 Designer' designer 'Qt;Development;GUIDesigner'
  47 }
  48
  49 pkg_postinst() {
  50         qt5-build_pkg_postinst
  51         xdg_icon_cache_update
  52 }
  53
  54 pkg_postrm() {
  55         qt5-build_pkg_postrm
  56         xdg_icon_cache_update
  57 }