dev-qt/assistant/assistant-5.14.1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 QT5_MODULE="qttools"
   6 inherit desktop qt5-build xdg-utils
   7
   8 DESCRIPTION="Tool for viewing on-line documentation in Qt help file format"
   9
  10 if [[ ${QT5_BUILD_TYPE} == release ]]; then
  11         KEYWORDS="amd64 ~arm arm64 ~hppa ppc64 ~sparc x86"
  12 fi
  13
  14 IUSE="webkit"
  15
  16 DEPEND="
  17         ~dev-qt/qtcore-${PV}
  18         ~dev-qt/qtgui-${PV}
  19         ~dev-qt/qthelp-${PV}
  20         ~dev-qt/qtnetwork-${PV}
  21         ~dev-qt/qtprintsupport-${PV}
  22         ~dev-qt/qtsql-${PV}[sqlite]
  23         ~dev-qt/qtwidgets-${PV}
  24         webkit? ( >=dev-qt/qtwebkit-5.9.1:5 )
  25 "
  26 RDEPEND="${DEPEND}"
  27
  28 QT5_TARGET_SUBDIRS=(
  29         src/assistant/assistant
  30 )
  31
  32 src_prepare() {
  33         qt_use_disable_mod webkit webkitwidgets \
  34                 src/assistant/assistant/assistant.pro
  35
  36         qt5-build_src_prepare
  37 }
  38
  39 src_install() {
  40         qt5-build_src_install
  41
  42         doicon -s 32 src/assistant/assistant/images/assistant.png
  43         newicon -s 128 src/assistant/assistant/images/assistant-128.png assistant.png
  44         make_desktop_entry "${QT5_BINDIR}"/assistant 'Qt 5 Assistant' assistant 'Qt;Development;Documentation'
  45 }
  46
  47 pkg_postinst() {
  48         qt5-build_pkg_postinst
  49         xdg_icon_cache_update
  50 }
  51
  52 pkg_postrm() {
  53         qt5-build_pkg_postrm
  54         xdg_icon_cache_update
  55 }