dev-python/zipp/zipp-0.6.0-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( pypy3 python{2_7,3_{6,7,8}} )
   7
   8 inherit distutils-r1
   9
  10 DESCRIPTION="Backport of pathlib-compatible object wrapper for zip files"
  11 HOMEPAGE="https://github.com/jaraco/zipp"
  12 SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
  13
  14 LICENSE="MIT"
  15 SLOT="0"
  16 KEYWORDS="~alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 s390 sparc x86"
  17 IUSE="test"
  18
  19 RDEPEND="dev-python/more-itertools[${PYTHON_USEDEP}]"
  20 BDEPEND="
  21         dev-python/setuptools[${PYTHON_USEDEP}]
  22         test? (
  23                 ${RDEPEND}
  24                 $(python_gen_cond_dep '
  25                         dev-python/contextlib2[${PYTHON_USEDEP}]
  26                         dev-python/pathlib2[${PYTHON_USEDEP}]
  27                         dev-python/unittest2[${PYTHON_USEDEP}]
  28                 ' pypy{,3} python{2_7,3_{5,6,7}})
  29         )
  30 "
  31
  32 distutils_enable_sphinx docs \
  33         ">=dev-python/jaraco-packaging-3.2" \
  34         ">=dev-python/rst-linker-1.9"
  35
  36 distutils_enable_tests pytest
  37
  38 python_prepare_all() {
  39         sed -i "s:use_scm_version=True:version='${PV}',name='${PN//-/.}':" setup.py || die
  40         sed -r -i "s:setuptools_scm[[:space:]]*([><=]{1,2}[[:space:]]*[0-9.a-zA-Z]+|)[[:space:]]*::" \
  41                 setup.cfg || die
  42         distutils-r1_python_prepare_all
  43 }