dev-python/mako/mako-1.1.1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 DISTUTILS_USE_SETUPTOOLS=rdepend
   7 PYTHON_COMPAT=( pypy3 python{2_7,3_{6,7,8}} )
   8
   9 inherit distutils-r1 eutils
  10
  11 MY_PN="Mako"
  12 MY_P=${MY_PN}-${PV}
  13
  14 DESCRIPTION="A Python templating language"
  15 HOMEPAGE="https://www.makotemplates.org/ https://pypi.org/project/Mako/"
  16 SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
  17 S="${WORKDIR}/${MY_P}"
  18
  19 LICENSE="MIT"
  20 SLOT="0"
  21 KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~ia64 ~m68k ~mips ppc ppc64 s390 sparc x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
  22 IUSE="doc"
  23
  24 RDEPEND=">=dev-python/markupsafe-0.9.2[${PYTHON_USEDEP}]"
  25
  26 DEPEND="
  27         test? (
  28                 $(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' -2)
  29         )
  30 "
  31
  32 PATCHES=(
  33         "${FILESDIR}"/mako-1.1.1-pypy3-test.patch
  34 )
  35
  36 distutils_enable_tests pytest
  37
  38 python_install_all() {
  39         rm -r doc/build || die
  40
  41         use doc && local HTML_DOCS=( doc/. )
  42         distutils-r1_python_install_all
  43 }
  44
  45 pkg_postinst() {
  46         elog "Optional dependencies:"
  47         optfeature "caching support" dev-python/beaker
  48 }