dev-python/llfuse/llfuse-1.3.4.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 PYTHON_COMPAT=( python{2_7,3_6} pypy3 )
   6
   7 inherit distutils-r1
   8
   9 DESCRIPTION="Python bindings for the low-level FUSE API"
  10 HOMEPAGE="https://bitbucket.org/nikratio/python-llfuse/ https://pypi.org/project/llfuse/"
  11 SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.bz2"
  12
  13 LICENSE="LGPL-2"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE="doc examples test"
  17 RESTRICT="!test? ( test )"
  18
  19 RDEPEND=">=sys-fs/fuse-2.8.0:0
  20         $(python_gen_cond_dep 'dev-python/contextlib2[${PYTHON_USEDEP}]' python2_7 pypy)
  21 "
  22 DEPEND="
  23         dev-python/setuptools[${PYTHON_USEDEP}]
  24         sys-apps/attr
  25         virtual/pkgconfig
  26         test? (
  27                 ${RDEPEND}
  28                 dev-python/pytest[${PYTHON_USEDEP}]
  29         )
  30 "
  31
  32 PATCHES=( "${FILESDIR}"/${PN}-1.3-cflags.patch )
  33
  34 python_test() {
  35         py.test -v || die "Tests failed under ${EPYTHON}"
  36 }
  37
  38 python_install_all() {
  39         use doc && local HTML_DOCS=( doc/html/. )
  40         use examples && dodoc -r examples
  41         distutils-r1_python_install_all
  42 }