dev-python/jaraco-envs/jaraco-envs-1.0.1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 PYTHON_COMPAT=( python3_{6,7,8} pypy3 )
   6 inherit distutils-r1
   7
   8 MY_PN="${PN//-/.}"
   9 MY_P="${MY_PN}-${PV}"
  10
  11 DESCRIPTION="Classes for orchestrating Python (virtual) environments."
  12 HOMEPAGE="https://github.com/jaraco/jaraco.envs"
  13 SRC_URI="https://github.com/jaraco/jaraco.envs/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  14
  15 LICENSE="MIT"
  16 SLOT="0"
  17 KEYWORDS="~amd64 ~hppa ~sparc ~x86"
  18
  19 RDEPEND="dev-python/namespace-jaraco[${PYTHON_USEDEP}]
  20         dev-python/path-py[${PYTHON_USEDEP}]
  21         $(python_gen_cond_dep 'dev-python/contextlib2[${PYTHON_USEDEP}]' 'python3_[67]')"
  22 BDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
  23
  24 # there are no actual tests, just flake8 etc
  25 RESTRICT="test"
  26
  27 S="${WORKDIR}/${MY_P}"
  28
  29 python_prepare_all() {
  30         # avoid a setuptools_scm dependency
  31         sed -i "s:use_scm_version=True:version='${PV}',name='${PN//-/.}':" setup.py || die
  32         sed -r -i "s:setuptools(_|-)scm[[:space:]]*([><=]{1,2}[[:space:]]*[0-9.a-zA-Z]+|)[[:space:]]*::" \
  33                 setup.cfg || die
  34
  35         distutils-r1_python_prepare_all
  36 }
  37
  38 python_install() {
  39         rm "${BUILD_DIR}"/lib/jaraco/__init__.py || die
  40         distutils-r1_python_install --skip-build
  41 }