dev-python/irc/irc-16.3.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 PYTHON_COMPAT=( python{2_7,3_{6,7}} )
   6
   7 inherit distutils-r1
   8
   9 DESCRIPTION="IRC client framework written in Python"
  10 HOMEPAGE="https://github.com/jaraco/irc"
  11 SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
  12
  13 LICENSE="MIT"
  14 SLOT="0"
  15 KEYWORDS="amd64 x86"
  16 IUSE="doc examples test"
  17 RESTRICT="!test? ( test )"
  18
  19 RDEPEND="
  20         >=dev-python/jaraco-functools-1.5[${PYTHON_USEDEP}]
  21         >=dev-python/jaraco-itertools-1.8[${PYTHON_USEDEP}]
  22         >=dev-python/tempora-1.6[${PYTHON_USEDEP}]
  23         dev-python/jaraco-collections[${PYTHON_USEDEP}]
  24         dev-python/jaraco-logging[${PYTHON_USEDEP}]
  25         dev-python/jaraco-stream[${PYTHON_USEDEP}]
  26         dev-python/jaraco-text[${PYTHON_USEDEP}]
  27         dev-python/more-itertools[${PYTHON_USEDEP}]
  28         dev-python/pytz[${PYTHON_USEDEP}]
  29         dev-python/six[${PYTHON_USEDEP}]
  30 "
  31 DEPEND="
  32         dev-python/setuptools[${PYTHON_USEDEP}]
  33         >=dev-python/setuptools_scm-1.15.0[${PYTHON_USEDEP}]
  34         doc? (
  35                 >=dev-python/jaraco-packaging-3.2[${PYTHON_USEDEP}]
  36                 >=dev-python/rst-linker-1.9[${PYTHON_USEDEP}]
  37                 dev-python/sphinx[${PYTHON_USEDEP}]
  38         )
  39         test? (
  40                 ${RDEPEND}
  41                 dev-python/backports-unittest-mock[${PYTHON_USEDEP}]
  42                 >=dev-python/pytest-2.8[${PYTHON_USEDEP}]
  43         )
  44 "
  45
  46 python_compile_all() {
  47         if use doc; then
  48                 cd docs || die
  49                 sphinx-build . _build/html || die
  50                 HTML_DOCS=( docs/_build/html/. )
  51         fi
  52 }
  53
  54 python_test() {
  55         # Override pytest options to skip flake8
  56         pytest -vv --override-ini="addopts=--doctest-modules" \
  57                 || die "Tests failed with ${EPYTHON}"
  58 }
  59
  60 python_install_all() {
  61         if use examples; then
  62                 docompress -x "/usr/share/doc/${PF}/scripts"
  63                 dodoc -r scripts
  64         fi
  65         distutils-r1_python_install_all
  66 }