dev-python/importlib_metadata/importlib_metadata-0.23-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( pypy3 python{2_7,3_{6,7,8}} )
   7
   8 inherit distutils-r1
   9
  10 DESCRIPTION="Read metadata from Python packages"
  11 HOMEPAGE="https://importlib-metadata.readthedocs.io/"
  12 SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
  13
  14 LICENSE="Apache-2.0"
  15 SLOT="0"
  16 KEYWORDS="~alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 s390 sparc x86"
  17 IUSE="test"
  18
  19 RDEPEND="
  20         dev-python/zipp[${PYTHON_USEDEP}]
  21         $(python_gen_cond_dep '>=dev-python/configparser-3.5[${PYTHON_USEDEP}]' -2)
  22         $(python_gen_cond_dep 'dev-python/contextlib2[${PYTHON_USEDEP}]' -2)
  23         $(python_gen_cond_dep 'dev-python/pathlib2[${PYTHON_USEDEP}]' -2)
  24 "
  25 BDEPEND="
  26         dev-python/setuptools[${PYTHON_USEDEP}]
  27         test? (
  28                 ${RDEPEND}
  29                 $(python_gen_cond_dep 'dev-python/importlib_resources[${PYTHON_USEDEP}]' pypy{,3} python{2_7,3_{5,6}})
  30                 dev-python/packaging[${PYTHON_USEDEP}]
  31         )
  32 "
  33
  34 PATCHES=(
  35         "${FILESDIR}/importlib_metadata-0.23-py38.patch"
  36 )
  37
  38 distutils_enable_sphinx "${PN}/docs" \
  39         '>=dev-python/rst-linker-1.9'
  40 distutils_enable_tests unittest
  41
  42 python_prepare_all() {
  43         # avoid a setuptools_scm dependency
  44         sed -i "s:use_scm_version=True:version='${PV}',name='${PN//-/.}':" setup.py || die
  45         sed -r -i "s:setuptools(_|-)scm[[:space:]]*([><=]{1,2}[[:space:]]*[0-9.a-zA-Z]+|)[[:space:]]*::" \
  46                 setup.cfg || die
  47
  48         distutils-r1_python_prepare_all
  49 }