dev-python/eventlet/eventlet-0.24.1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python2_7 python3_6 )
   7
   8 inherit distutils-r1
   9
  10 DESCRIPTION="Highly concurrent networking library"
  11 HOMEPAGE="https://pypi.org/project/eventlet/ https://github.com/eventlet/eventlet/"
  12 SRC_URI="mirror://pypi/e/${PN}/${P}.tar.gz"
  13
  14 LICENSE="MIT"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~arm64 ~x86"
  17 IUSE="doc examples test"
  18 RESTRICT="!test? ( test )"
  19
  20 RDEPEND="
  21         >=dev-python/dnspython-1.15.0[${PYTHON_USEDEP}]
  22         virtual/python-enum34[${PYTHON_USEDEP}]
  23         >=dev-python/greenlet-0.3[${PYTHON_USEDEP}]
  24         >=dev-python/monotonic-1.4[${PYTHON_USEDEP}]
  25         >=dev-python/six-1.10.0[${PYTHON_USEDEP}]"
  26 DEPEND="doc? ( dev-python/sphinx[${PYTHON_USEDEP}]
  27                 >=dev-python/python-docs-2.7.6-r1:2.7 )
  28         test? ( ${RDEPEND}
  29                 dev-python/pyopenssl[${PYTHON_USEDEP}]
  30                 dev-python/nose[${PYTHON_USEDEP}] )"
  31
  32 python_prepare_all() {
  33         # provided by virtual/python-enum34
  34         sed -i '/enum-compat/d' setup.py || die
  35
  36         if use doc; then
  37                 local PYTHON_DOC_ATOM=$(best_version -b dev-python/python-docs:2.7)
  38                 local PYTHON_DOC_VERSION="${PYTHON_DOC_ATOM#dev-python/python-docs-}"
  39                 local PYTHON_DOC="/usr/share/doc/python-docs-${PYTHON_DOC_VERSION}/html"
  40                 local PYTHON_DOC_INVENTORY="${PYTHON_DOC}/objects.inv"
  41                 sed -i "s|'http://docs.python.org/': None|'${PYTHON_DOC}': '${PYTHON_DOC_INVENTORY}'|" doc/conf.py || die
  42         fi
  43
  44         if use test; then
  45 #               sed -i '/This is a Python 3 module/d' eventlet/green/http/__init__.py || die
  46 #               sed -i 's/^import/from OpenSSL import/g' eventlet/green/OpenSSL/__init__.py || die
  47 #               sed -i 's/^from version/from OpenSSL.version/' eventlet/green/OpenSSL/__init__.py || die
  48                 sed -i 's/TEST_TIMEOUT = 1/TEST_TIMEOUT = 10/' tests/__init__.py || die
  49         fi
  50
  51         # Prevent file collisions from teestsuite
  52         sed -e "s:'tests', :'tests', 'tests.*', :" -i setup.py || die
  53
  54         distutils-r1_python_prepare_all
  55 }
  56
  57 python_compile_all() {
  58         # https://github.com/eventlet/eventlet/issues/152
  59         use doc && emake -C doc html
  60 }
  61
  62 python_test() {
  63         # Several errors 1 failure
  64         # https://github.com/eventlet/eventlet/issues/151
  65         nosetests tests || die "Tests fail with ${EPYTHON}"
  66 }
  67
  68 python_install_all() {
  69         use doc && local HTML_DOCS=( doc/_build/html/. )
  70         if use examples; then
  71                 docompress -x "/usr/share/doc/${PF}/examples"
  72                 docinto examples
  73                 dodoc -r examples/.
  74         fi
  75         distutils-r1_python_install_all
  76 }