dev-python/argon2_cffi/argon2_cffi-19.1.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{6,7,8} pypy3 )
   7 inherit distutils-r1
   8
   9 DESCRIPTION="CFFI bindings to the Argon2 password hashing library"
  10 HOMEPAGE="https://github.com/hynek/argon2-cffi"
  11 SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
  12
  13 LICENSE="MIT"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86"
  16
  17 COMMON_DEPEND="
  18         app-crypt/argon2:=
  19         dev-python/six[${PYTHON_USEDEP}]
  20         virtual/python-cffi[${PYTHON_USEDEP}]
  21         virtual/python-enum34[${PYTHON_USEDEP}]
  22 "
  23 RDEPEND="${COMMON_DEPEND}"
  24 DEPEND="${COMMON_DEPEND}
  25         dev-python/setuptools[${PYTHON_USEDEP}]
  26         test? (
  27                 dev-python/hypothesis[${PYTHON_USEDEP}]
  28         )
  29 "
  30
  31 DOCS=( AUTHORS.rst CHANGELOG.rst FAQ.rst README.rst )
  32
  33 distutils_enable_sphinx docs
  34 distutils_enable_tests pytest
  35
  36 python_configure_all() {
  37         export ARGON2_CFFI_USE_SYSTEM=1
  38 }