dev-python/aiohttp/aiohttp-3.6.1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{6,7,8} )
   7
   8 inherit distutils-r1
   9
  10 DESCRIPTION="http client/server for asyncio"
  11 HOMEPAGE="https://pypi.org/project/aiohttp/"
  12 SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz -> ${P}.tar.gz"
  13
  14 LICENSE="Apache-2.0"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~arm ~arm64 ~x86"
  17 IUSE="doc test"
  18 RESTRICT="!test? ( test )"
  19
  20 CDEPEND="
  21         >=dev-python/async_timeout-3.0.0[${PYTHON_USEDEP}]
  22         >=dev-python/attrs-17.3.0[${PYTHON_USEDEP}]
  23         dev-python/chardet[${PYTHON_USEDEP}]
  24         >=dev-python/multidict-4.5.0[${PYTHON_USEDEP}]
  25         >=dev-python/yarl-1.0[${PYTHON_USEDEP}]
  26         dev-python/idna-ssl[${PYTHON_USEDEP}]
  27         $(python_gen_cond_dep 'dev-python/typing-extensions[${PYTHON_USEDEP}]' \
  28                 python3_{5,6})
  29 "
  30 DEPEND="
  31         dev-python/setuptools[${PYTHON_USEDEP}]
  32         dev-python/cython[${PYTHON_USEDEP}]
  33         doc? (
  34                 >=dev-python/alabaster-0.6.2[${PYTHON_USEDEP}]
  35                 dev-python/sphinxcontrib-asyncio[${PYTHON_USEDEP}]
  36                 dev-python/sphinxcontrib-blockdiag[${PYTHON_USEDEP}]
  37                 dev-python/sphinxcontrib-newsfeed[${PYTHON_USEDEP}]
  38                 dev-python/sphinxcontrib-spelling[${PYTHON_USEDEP}]
  39                 dev-python/sphinx[${PYTHON_USEDEP}]
  40                 dev-python/sphinx-aiohttp-theme[${PYTHON_USEDEP}]
  41         )
  42         test? (
  43                 ${CDEPEND}
  44                 dev-python/async_generator[${PYTHON_USEDEP}]
  45                 dev-python/brotlipy[${PYTHON_USEDEP}]
  46                 >=dev-python/pytest-3.4.0[${PYTHON_USEDEP}]
  47                 dev-python/pytest-mock[${PYTHON_USEDEP}]
  48                 dev-python/pytest-timeout[${PYTHON_USEDEP}]
  49                 dev-python/trustme[${PYTHON_USEDEP}]
  50                 www-servers/gunicorn[${PYTHON_USEDEP}]
  51         )
  52 "
  53 RDEPEND="${CDEPEND}"
  54
  55 DOCS=( CHANGES.rst CONTRIBUTING.rst CONTRIBUTORS.txt HISTORY.rst README.rst )
  56
  57 python_prepare_all() {
  58         # FIXME
  59         rm tests/test_pytest_plugin.py || die
  60         sed -i -e 's:test_testcase_no_app:_&:' tests/test_test_utils.py || die
  61
  62         # remove pointless dep on pytest-cov
  63         sed -i -e '/addopts/s/--cov=aiohttp//' pytest.ini || die
  64
  65         distutils-r1_python_prepare_all
  66 }
  67
  68 python_compile_all() {
  69         use doc && emake -C docs html
  70 }
  71
  72 python_test() {
  73         pytest -vv || die "Tests fail with ${EPYTHON}"
  74 }
  75
  76 python_install_all() {
  77         use doc && local HTML_DOCS=( docs/_build/html/. )
  78
  79         distutils-r1_python_install_all
  80 }