dev-libs/tvision/tvision-2.2.1.4.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 MY_PV=$(ver_rs 3 -)
   7
   8 DESCRIPTION="Text User Interface that implements the well known CUA widgets"
   9 HOMEPAGE="http://tvision.sourceforge.net/"
  10 SRC_URI="mirror://sourceforge/tvision/rhtvision_${MY_PV}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~ppc ~x86"
  15 IUSE="+X debug gpm"
  16
  17 DOCS=( readme.txt THANKS TODO )
  18 HTML_DOCS=( www-site/. )
  19
  20 S=${WORKDIR}/${PN}
  21
  22 # installed lib links to those
  23 RDEPEND="
  24         dev-libs/libbsd
  25         sys-apps/util-linux
  26         sys-libs/ncurses:0=
  27         gpm? ( sys-libs/gpm )
  28         X? (
  29                 x11-libs/libICE
  30                 x11-libs/libSM
  31                 x11-libs/libX11
  32                 x11-libs/libXau
  33                 x11-libs/libXdmcp
  34                 x11-libs/libXext
  35                 x11-libs/libXmu
  36                 x11-libs/libXt
  37                 x11-libs/libxcb:=
  38         )"
  39 DEPEND="${RDEPEND}"
  40
  41 PATCHES=(
  42         "${FILESDIR}/${P}-fix-dot-INC.patch"
  43         "${FILESDIR}/${P}-ldconfig.patch"
  44         "${FILESDIR}/${P}-build-system.patch"
  45         "${FILESDIR}/${P}-gcc6.patch"
  46         "${FILESDIR}/${P}-flags.patch"
  47         "${FILESDIR}/${P}-fix-overloaded-abs.patch"
  48 )
  49
  50 src_configure() {
  51         # Note: Do not use econf here, this isn't an autoconf configure script,
  52         # but a perl based script which simply calls config.pl
  53         ./configure --fhs \
  54                 $(use_with debug debug) \
  55                 --without-static \
  56         || die
  57 }
  58
  59 src_install() {
  60         emake DESTDIR="${D}" install \
  61                 prefix="\${DESTDIR}/${EPREFIX}/usr" \
  62                 libdir="\$(prefix)/$(get_libdir)"
  63
  64         einstalldocs
  65         dosym rhtvision /usr/include/tvision
  66
  67         # remove CVS directory which gets copied over
  68         rm -r "${ED}/usr/share/doc/${P}/html/CVS" || die
  69 }