dev-libs/skalibs/skalibs-2.6.1.0.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit versionator
   7
   8 DESCRIPTION="skarnet.org general-purpose libraries"
   9 HOMEPAGE="https://www.skarnet.org/software/skalibs/"
  10 SRC_URI="https://www.skarnet.org/software/${PN}/${P}.tar.gz"
  11
  12 LICENSE="ISC"
  13 SLOT="0/$(get_version_component_range 1-2)"
  14 KEYWORDS="~amd64 ~arm ~x86"
  15 IUSE="doc ipv6 static-libs"
  16
  17 DEPEND=">=sys-devel/make-3.81"
  18 RDEPEND=""
  19
  20 HTML_DOCS="doc/*"
  21
  22 src_prepare() {
  23         default
  24
  25         # Remove QA warning about LDFLAGS addition
  26         sed -i "s/tryldflag LDFLAGS_AUTO -Wl,--hash-style=both/:/" "${S}/configure" || die
  27
  28         # configure overrides gentoo's -fstack-protector default
  29         sed -i "/^tryflag CFLAGS -fno-stack-protector$/d" "${S}/configure" || die
  30 }
  31
  32 src_configure() {
  33         econf \
  34                 --datadir=/etc \
  35                 --dynlibdir=/$(get_libdir) \
  36                 --libdir=/usr/$(get_libdir)/${PN} \
  37                 --sysdepdir=/usr/$(get_libdir)/${PN} \
  38                 --enable-clock \
  39                 --enable-shared \
  40                 $(use_enable static-libs static) \
  41                 $(use_enable ipv6)
  42 }
  43
  44 src_install() {
  45         emake DESTDIR="${D}" install
  46
  47         use doc && einstalldocs
  48 }