dev-libs/mpfr/mpfr-4.0.1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 # NOTE: we cannot depend on autotools here starting with gcc-4.3.x
   7 inherit libtool multilib-minimal preserve-libs
   8
   9 MY_PV=${PV/_p*}
  10 MY_P=${PN}-${MY_PV}
  11 PLEVEL=${PV/*p}
  12 DESCRIPTION="library for multiple-precision floating-point computations with exact rounding"
  13 HOMEPAGE="https://www.mpfr.org/"
  14 SRC_URI="https://www.mpfr.org/mpfr-${MY_PV}/${MY_P}.tar.xz"
  15
  16 LICENSE="LGPL-2.1"
  17 SLOT="0/6" # libmpfr.so version
  18 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  19 IUSE="static-libs"
  20
  21 RDEPEND=">=dev-libs/gmp-5.0.0[${MULTILIB_USEDEP},static-libs?]"
  22 DEPEND="${RDEPEND}"
  23
  24 S=${WORKDIR}/${MY_P}
  25
  26 HTML_DOCS=( doc/FAQ.html )
  27
  28 src_prepare() {
  29         if [[ ${PLEVEL} != ${PV} ]] ; then
  30                 local i
  31                 for (( i = 1; i <= PLEVEL; ++i )) ; do
  32                         eapply "${FILESDIR}"/${MY_PV}/patch$(printf '%02d' ${i})
  33                 done
  34         fi
  35         eapply_user
  36         find . -type f -exec touch -r configure {} +
  37         elibtoolize
  38 }
  39
  40 multilib_src_configure() {
  41         # Make sure mpfr doesn't go probing toolchains it shouldn't #476336#19
  42         ECONF_SOURCE=${S} \
  43         user_redefine_cc=yes \
  44         econf $(use_enable static-libs static)
  45 }
  46
  47 multilib_src_install_all() {
  48         rm "${ED}"/usr/share/doc/"${P}"/COPYING*
  49         use static-libs || find "${ED}"/usr -name '*.la' -delete
  50 }
  51
  52 pkg_preinst() {
  53         preserve_old_lib /usr/$(get_libdir)/libmpfr$(get_libname 4)
  54 }
  55
  56 pkg_postinst() {
  57         preserve_old_lib_notify /usr/$(get_libdir)/libmpfr$(get_libname 4)
  58 }