dev-libs/libedit/libedit-20191211.3.1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="7"
   5 inherit autotools multilib-minimal toolchain-funcs usr-ldscript
   6
   7 MY_PV=${PV/./-}
   8 MY_P=${PN}-${MY_PV}
   9
  10 DESCRIPTION="BSD replacement for libreadline"
  11 HOMEPAGE="https://thrysoee.dk/editline/"
  12 SRC_URI="https://thrysoee.dk/editline/${MY_P}.tar.gz"
  13 S=${WORKDIR}/${MY_P}
  14
  15 LICENSE="BSD-2"
  16 SLOT="0"
  17 KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
  18 IUSE="static-libs"
  19
  20 RDEPEND=">=sys-libs/ncurses-5.9-r3[static-libs?,${MULTILIB_USEDEP}]"
  21 DEPEND=${RDEPEND}
  22
  23 PATCHES=(
  24         "${FILESDIR}/${PN}-20170329.3.1-tinfo.patch"
  25 )
  26
  27 src_prepare() {
  28         default
  29         eautoreconf
  30 }
  31
  32 multilib_src_configure() {
  33         ECONF_SOURCE="${S}" econf \
  34                 $(use_enable static-libs static) \
  35                 --enable-widec \
  36                 --enable-fast-install
  37 }
  38
  39 multilib_src_install() {
  40         emake DESTDIR="${D}" install
  41         gen_usr_ldscript -a edit
  42 }
  43
  44 multilib_src_install_all() {
  45         einstalldocs
  46         find "${D}" -name '*.la' -delete || die
  47         # file collision with sys-libs/readline
  48         rm "${ED}/usr/share/man/man3/history.3" || die
  49 }