dev-libs/gmime/gmime-3.2.5.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 VALA_USE_DEPEND="vapigen"
   6
   7 inherit flag-o-matic gnome2 vala
   8
   9 DESCRIPTION="Utilities for creating and parsing messages using MIME"
  10 HOMEPAGE="http://spruce.sourceforge.net/gmime/ https://developer.gnome.org/gmime/stable/"
  11
  12 SLOT="3.0"
  13 LICENSE="LGPL-2.1+"
  14 KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~ia64 ppc ppc64 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x64-solaris ~x86-solaris"
  15 IUSE="crypt doc idn static-libs test vala"
  16 RESTRICT="!test? ( test )"
  17
  18 RDEPEND="
  19         >=dev-libs/glib-2.32.0:2
  20         sys-libs/zlib
  21         crypt? ( >=app-crypt/gpgme-1.8.0:1= )
  22         idn? ( net-dns/libidn2:= )
  23         vala? (
  24                 $(vala_depend)
  25                 >=dev-libs/gobject-introspection-1.30.0:= )
  26 "
  27 DEPEND="${RDEPEND}
  28         >=dev-util/gtk-doc-am-1.8
  29         virtual/libiconv
  30         virtual/pkgconfig
  31         doc? ( app-text/docbook-sgml-utils )
  32         test? ( app-crypt/gnupg )
  33 "
  34 # gnupg is needed for tests if --enable-cryptography is enabled, which we do unconditionally
  35
  36 src_prepare() {
  37         gnome2_src_prepare
  38         use vala && vala_src_prepare
  39 }
  40
  41 src_configure() {
  42         if [[ ${CHOST} == *-solaris* ]]; then
  43                 # bug #???, why not use --with-libiconv
  44                 append-libs iconv
  45         fi
  46
  47         gnome2_src_configure \
  48                 $(use_enable crypt crypto) \
  49                 $(use_enable static-libs static) \
  50                 $(use_enable vala) \
  51                 $(use_with idn libidn) \
  52                 $(usex doc "" DB2HTML=)
  53 }
  54
  55 src_compile() {
  56         gnome2_src_compile
  57         if use doc; then
  58                 emake -C docs/tutorial html
  59         fi
  60 }
  61
  62 src_install() {
  63         gnome2_src_install
  64
  65         if use doc ; then
  66                 docinto tutorial
  67                 dodoc -r docs/tutorial/html/
  68         fi
  69 }