dev-java/swingx-ws/swingx-ws-1.0_p20110515-r1.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 MY_P="${PN}-2011_05_15-src"
   7 JAVA_PKG_IUSE="doc source"
   8
   9 inherit java-pkg-2 java-pkg-simple
  10
  11 DESCRIPTION="Utilities and widgets to integrate Swing GUIs with web applications"
  12 HOMEPAGE="https://java.net/projects/swingx-ws/"
  13 SRC_URI="mirror://sourceforge/bt747/Development/${MY_P}.zip"
  14 LICENSE="LGPL-2.1"
  15 SLOT="bt747"
  16 KEYWORDS="~amd64 ~x86"
  17
  18 CP_DEPEND="
  19         dev-java/jdom:0
  20         dev-java/json:0
  21         dev-java/rome:0
  22         dev-java/jtidy:0
  23         dev-java/xerces:2
  24         dev-java/swingx:1.6
  25         dev-java/swing-layout:1
  26         dev-java/swingx-beaninfo:0
  27         dev-java/commons-httpclient:3
  28         dev-java/xml-commons-external:1.4"
  29
  30 RDEPEND="
  31         ${CP_DEPEND}
  32         >=virtual/jre-1.6"
  33
  34 DEPEND="
  35         ${CP_DEPEND}
  36         >=virtual/jdk-1.6
  37         app-arch/unzip"
  38
  39 S="${WORKDIR}/${MY_P}/src"
  40 JAVA_SRC_DIR="beaninfo java"
  41
  42 src_prepare() {
  43         default
  44         java-pkg_clean "${WORKDIR}"
  45
  46         # SwingWorker has been built-in since Java 6.
  47         find java -name "*.java" -exec sed -i -r "s:org\.jdesktop\.swingworker\.:javax.swing.:g" {} + || die
  48
  49         # Fixes for newer swingx-beaninfo.
  50         sed -i "s:BeanInfoSupport:org.jdesktop.beans.\0:g" beaninfo/org/jdesktop/swingx/*.java || die
  51         find beaninfo -name "*.java" -exec sed -i -r "s:org\.jdesktop\.swingx\.(editors|BeanInfoSupport|EnumerationValue):org.jdesktop.beans.\1:g" {} + || die
  52
  53         # GraphicsUtilities moved in later SwingX versions.
  54         sed -i "s:org\.jdesktop\.swingx\.graphics\.GraphicsUtilities:org.jdesktop.swingx.util.GraphicsUtilities:g" \
  55                 java/org/jdesktop/swingx/mapviewer/AbstractTileFactory.java || die
  56
  57         java-pkg-2_src_prepare
  58 }
  59
  60 src_compile() {
  61         java-pkg-simple_src_compile
  62
  63         local DIR
  64         for DIR in ${JAVA_SRC_DIR}; do
  65                 java-pkg_addres ${PN}.jar ${DIR}
  66         done
  67 }