dev-java/openjdk-jre-bin/openjdk-jre-bin-8.252_p09.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit eapi7-ver java-vm-2
   7
   8 abi_uri() {
   9         echo "${2-$1}? (
  10                         https://github.com/AdoptOpenJDK/openjdk${SLOT}-binaries/releases/download/jdk${MY_PV}/OpenJDK8U-jre_${1}_linux_hotspot_${MY_PV/-/}.tar.gz
  11                 )"
  12 }
  13
  14 MY_PV=$(ver_rs 1 'u' 2 '-' ${PV//p/b})
  15 SLOT="$(ver_cut 1)"
  16
  17 DESCRIPTION="Prebuilt Java JRE binaries provided by AdoptOpenJDK"
  18 HOMEPAGE="https://adoptopenjdk.net"
  19 SRC_URI="
  20         $(abi_uri x64 amd64)
  21 "
  22
  23 LICENSE="GPL-2-with-classpath-exception"
  24 KEYWORDS="~amd64"
  25
  26 IUSE="alsa cups headless-awt nsplugin selinux webstart"
  27
  28 RDEPEND="
  29         media-libs/fontconfig:1.0
  30         media-libs/freetype:2
  31         >net-libs/libnet-1.1
  32         >=sys-apps/baselayout-java-0.1.0-r1
  33         >=sys-libs/glibc-2.2.5:*
  34         sys-libs/zlib
  35         alsa? ( media-libs/alsa-lib )
  36         cups? ( net-print/cups )
  37         selinux? ( sec-policy/selinux-java )
  38         !headless-awt? (
  39                 x11-libs/libX11
  40                 x11-libs/libXext
  41                 x11-libs/libXi
  42                 x11-libs/libXrender
  43                 x11-libs/libXtst
  44         )"
  45
  46 PDEPEND="
  47         webstart? ( >=dev-java/icedtea-web-1.6.1:0 )
  48         nsplugin? ( >=dev-java/icedtea-web-1.6.1:0[nsplugin] )"
  49
  50 RESTRICT="preserve-libs splitdebug"
  51 QA_PREBUILT="*"
  52
  53 S="${WORKDIR}/jdk${MY_PV}-jre"
  54
  55 src_install() {
  56         local dest="/opt/${P}"
  57         local ddest="${ED%/}/${dest#/}"
  58
  59         rm ASSEMBLY_EXCEPTION LICENSE THIRD_PARTY_README || die
  60
  61         # this does not exist on arm64 hence -f
  62         rm -fv lib/*/libfreetype.so* || die
  63
  64         if ! use alsa ; then
  65                 rm -v lib/*/libjsoundalsa.so* || die
  66         fi
  67
  68         if use headless-awt ; then
  69                 rm -fvr lib/*/lib*{[jx]awt,splashscreen}* \
  70                         bin/policytool || die
  71         fi
  72
  73         rm -v lib/security/cacerts || die
  74         dosym ../../../../../etc/ssl/certs/java/cacerts \
  75                 "${dest}"/lib/security/cacerts
  76
  77         dodir "${dest}"
  78         cp -pPR * "${ddest}" || die
  79
  80         java-vm_install-env "${FILESDIR}"/${PN}-${SLOT}.env.sh
  81         java-vm_set-pax-markings "${ddest}"
  82         java-vm_revdep-mask
  83         java-vm_sandbox-predict /dev/random /proc/self/coredump_filter
  84 }