dev-java/hibernate/hibernate-3.1.3-r5.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="5"
   6
   7 WANT_ANT_TASKS="ant-antlr ant-swing ant-junit"
   8 JAVA_PKG_IUSE="doc source"
   9 JAVA_PKG_WANT_BOOTCLASSPATH="1.5"
  10
  11 inherit java-pkg-2 java-ant-2
  12
  13 MY_PV="3.1"
  14 DESCRIPTION="A powerful, ultra-high performance object / relational persistence and query service for Java"
  15 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
  16 HOMEPAGE="http://www.hibernate.org"
  17 LICENSE="LGPL-2"
  18 IUSE=""
  19 SLOT="3.1"
  20 KEYWORDS="~amd64 ~x86"
  21
  22 CDEPENDEND="
  23         >=dev-java/antlr-2.7.7:0[java]
  24         dev-java/c3p0:0
  25         dev-java/cglib:3
  26         dev-java/commons-collections:0
  27         dev-java/commons-logging:0
  28         dev-java/dom4j:1
  29         dev-java/ehcache:1.2
  30         dev-java/oscache:0
  31         dev-java/proxool:0
  32         dev-java/swarmcache:1.0
  33         java-virtuals/transaction-api:0
  34         dev-java/sun-jacc-api:0
  35         dev-java/ant-core:0
  36         dev-java/asm:2.2"
  37 RDEPEND=">=virtual/jre-1.6
  38         ${CDEPENDEND}"
  39 DEPEND=">=virtual/jdk-1.6
  40         ${CDEPENDEND}"
  41
  42 S="${WORKDIR}/${PN}-${MY_PV}"
  43
  44 JAVA_ANT_ENCODING="ISO-8859-1"
  45
  46 PATCHES=(
  47         "${FILESDIR}"/"${P}-EhCache.java.patch"
  48 )
  49
  50 java_prepare() {
  51         epatch "${PATCHES[@]}"
  52
  53         java-ant_rewrite-bootclasspath 1.5
  54
  55         # this depends on jboss
  56         rm src/org/hibernate/cache/JndiBoundTreeCacheProvider.java \
  57                 src/org/hibernate/cache/TreeCache.java \
  58                 src/org/hibernate/cache/TreeCacheProvider.java
  59
  60         rm -v *.jar lib/*.jar || die
  61 }
  62
  63 JAVA_ANT_REWRITE_CLASSPATH="true"
  64 EANT_GENTOO_CLASSPATH="
  65 c3p0,commons-collections,commons-logging,cglib-3,transaction-api
  66 dom4j-1,ehcache-1.2,oscache,proxool,swarmcache-1.0
  67 sun-jacc-api,antlr,ant-core,asm-2.2
  68 "
  69 EANT_EXTRA_ARGS="-Dnosplash -Ddist.dir=dist"
  70
  71 src_install() {
  72         java-pkg_dojar hibernate3.jar
  73         dodoc changelog.txt readme.txt
  74         use doc && java-pkg_dohtml -r doc/api doc/other doc/reference
  75         use source && java-pkg_dosrc src/*
  76 }