app-text/docbook-xml-simple-dtd/docbook-xml-simple-dtd-4.1.2.5-r3.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 inherit sgml-catalog-r1
   6
   7 MY_P=simple${PV//./}
   8 DESCRIPTION="Simplified Docbook DTD for XML"
   9 HOMEPAGE="https://www.oasis-open.org/docbook/xml/simple/4.1.2.5/"
  10 SRC_URI="https://www.oasis-open.org/docbook/xml/simple/${PV}/${MY_P}.zip"
  11
  12 LICENSE="docbook"
  13 SLOT="${PV}"
  14 KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 m68k ~mips ppc ppc64 s390 sparc x86 ~amd64-linux ~x86-linux ~x86-macos ~sparc-solaris"
  15 IUSE=""
  16
  17 RDEPEND=">=app-text/build-docbook-catalog-1.6"
  18 DEPEND=">=app-arch/unzip-5.41"
  19
  20 S=${WORKDIR}
  21
  22 src_install() {
  23         insinto /usr/share/sgml/docbook/${P#docbook-}
  24         doins *.dtd *.mod *.css
  25         newins "${FILESDIR}"/${P}.catalog catalog
  26
  27         insinto /etc/sgml
  28         newins - "xml-simple-docbook-${PV}.cat" <<-EOF
  29                 CATALOG "${EPREFIX}/usr/share/sgml/docbook/xml-simple-dtd-${PV}/catalog"
  30         EOF
  31 }
  32
  33 pkg_preinst() {
  34         # work-around old revision removing it
  35         cp "${ED}"/etc/sgml/xml-simple-docbook-${PV}.cat "${T}" || die
  36 }
  37
  38 pkg_postinst() {
  39         local backup=${T}/xml-simple-docbook-${PV}.cat
  40         local real=${EROOT}/etc/sgml/xml-simple-docbook-${PV}.cat
  41         if ! cmp -s "${backup}" "${real}"; then
  42                 cp "${backup}" "${real}" || die
  43         fi
  44         build-docbook-catalog
  45         sgml-catalog-r1_pkg_postinst
  46 }
  47
  48 pkg_postrm() {
  49         build-docbook-catalog
  50         sgml-catalog-r1_pkg_postrm
  51 }