app-text/docbook-sgml-dtd/docbook-sgml-dtd-4.4-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 inherit sgml-catalog-r1
   6
   7 MY_P="docbook-${PV}"
   8 DESCRIPTION="Docbook SGML DTD ${PV}"
   9 HOMEPAGE="https://docbook.org/sgml/"
  10 SRC_URI="https://docbook.org/sgml/${PV}/${MY_P}.zip"
  11
  12 LICENSE="docbook"
  13 SLOT="${PV}"
  14 KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 m68k ~mips ppc ppc64 s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~sparc-solaris ~x64-solaris"
  15 IUSE=""
  16
  17 DEPEND=">=app-arch/unzip-5.41"
  18
  19 S="${WORKDIR}"
  20 PATCHES=( "${FILESDIR}"/${P}-catalog.diff )
  21
  22 src_install() {
  23         insinto /usr/share/sgml/docbook/sgml-dtd-${PV}
  24         doins *.dcl *.dtd *.mod
  25         newins docbook.cat catalog
  26         insinto /etc/sgml
  27         newins - sgml-docbook-${PV}.cat <<-EOF
  28                 CATALOG "${EPREFIX}/usr/share/sgml/docbook/sgml-dtd-${PV}/catalog"
  29                 CATALOG "${EPREFIX}/etc/sgml/sgml-docbook.cat"
  30         EOF
  31         dodoc ChangeLog README
  32 }
  33
  34 pkg_preinst() {
  35         # work-around -r0 postrm removing it
  36         cp "${ED}"/etc/sgml/sgml-docbook-${PV}.cat "${T}" || die
  37 }
  38
  39 pkg_postinst() {
  40         local backup=${T}/sgml-docbook-${PV}.cat
  41         local real=${EROOT}/etc/sgml/sgml-docbook-${PV}.cat
  42         if ! cmp -s "${backup}" "${real}"; then
  43                 cp "${backup}" "${real}" || die
  44         fi
  45         sgml-catalog-r1_pkg_postinst
  46 }