app-portage/grs/grs-0.7.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="7"
   5 PYTHON_COMPAT=( python3_6 )
   6
   7 inherit distutils-r1 linux-info
   8
   9 ISO="ISO-1.tar.gz"
  10
  11 if [[ ${PV} == *9999 ]] ; then
  12         EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/grss.git"
  13         SRC_URI="https://dev.gentoo.org/~blueness/${PN}/${ISO}"
  14         inherit git-r3
  15 else
  16         SRC_URI="https://dev.gentoo.org/~blueness/${PN}/${P}.tar.gz
  17         https://dev.gentoo.org/~blueness/${PN}/${ISO}"
  18         KEYWORDS="amd64 arm arm64 x86"
  19 fi
  20
  21 DESCRIPTION="Suite to build Gentoo Reference Systems"
  22 HOMEPAGE="https://dev.gentoo.org/~blueness/grs"
  23
  24 LICENSE="GPL-2"
  25 SLOT="0"
  26 IUSE="server"
  27
  28 DEPEND=""
  29 RDEPEND="
  30         sys-apps/portage
  31         server? (
  32                 app-arch/tar[xattr]
  33                 app-crypt/md5deep
  34                 dev-libs/libcgroup
  35                 dev-vcs/git
  36                 net-misc/rsync
  37                 sys-fs/squashfs-tools
  38                 virtual/cdrtools
  39                 || (
  40                         sys-kernel/genkernel
  41                         sys-kernel/genkernel-next
  42                 )
  43         )"
  44
  45 pkg_setup() {
  46         if use server; then
  47                 local CONFIG_CHECK="~CGROUPS"
  48                 local ERROR_CGROUPS="WARNING: grsrun requires CONFIG_CGROUPS enabled in the kernel."
  49                 linux-info_pkg_setup
  50         fi
  51 }
  52
  53 src_install() {
  54         distutils-r1_src_install
  55         echo "CONFIG_PROTECT=\"/etc/grs/systems.conf\"" > "${T}"/20grs
  56         doenvd "${T}"/20grs
  57         if use server; then
  58                 mkdir "${D}"/usr/share/${PN}
  59                 cp "${DISTDIR}"/${ISO} "${D}"/usr/share/${PN}
  60         fi
  61 }