app-emulation/virtualbox/virtualbox-6.1.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python{2_7,3_{6,7,8}} )
   7 inherit desktop flag-o-matic java-pkg-opt-2 linux-info pax-utils python-single-r1 tmpfiles toolchain-funcs udev xdg
   8
   9 MY_PV="${PV/beta/BETA}"
  10 MY_PV="${MY_PV/rc/RC}"
  11 MY_P=VirtualBox-${MY_PV}
  12
  13 DESCRIPTION="Family of powerful x86 virtualization products for enterprise and home use"
  14 HOMEPAGE="https://www.virtualbox.org/"
  15 SRC_URI="https://download.virtualbox.org/virtualbox/${MY_PV}/${MY_P}.tar.bz2
  16         https://dev.gentoo.org/~polynomial-c/${PN}/patchsets/${PN}-6.1.0_rc1-patches-01.tar.xz"
  17
  18 LICENSE="GPL-2 dtrace? ( CDDL )"
  19 SLOT="0"
  20 [[ "${PV}" == *_beta* ]] || [[ "${PV}" == *_rc* ]] || \
  21 KEYWORDS="~amd64"
  22 IUSE="alsa debug doc dtrace headless java libressl lvm +opus pam pax_kernel pulseaudio +opengl python +qt5 +sdk +udev vboxwebsrv vnc"
  23
  24 CDEPEND="
  25         ${PYTHON_DEPS}
  26         !app-emulation/virtualbox-bin
  27         ~app-emulation/virtualbox-modules-${PV}
  28         dev-libs/libIDL
  29         >=dev-libs/libxslt-1.1.19
  30         net-misc/curl
  31         dev-libs/libxml2
  32         media-libs/libpng:0=
  33         media-libs/libvpx:0=
  34         sys-libs/zlib:=
  35         !headless? (
  36                 media-libs/libsdl:0[X,video]
  37                 x11-libs/libX11
  38                 x11-libs/libxcb:=
  39                 x11-libs/libXcursor
  40                 x11-libs/libXext
  41                 x11-libs/libXmu
  42                 x11-libs/libXt
  43                 opengl? ( virtual/opengl media-libs/freeglut )
  44                 qt5? (
  45                         dev-qt/qtcore:5
  46                         dev-qt/qtgui:5
  47                         dev-qt/qtprintsupport:5
  48                         dev-qt/qtwidgets:5
  49                         dev-qt/qtx11extras:5
  50                         opengl? ( dev-qt/qtopengl:5 )
  51                         x11-libs/libXinerama
  52                 )
  53         )
  54         libressl? ( dev-libs/libressl:= )
  55         !libressl? ( dev-libs/openssl:0= )
  56         lvm? ( sys-fs/lvm2 )
  57         opus? ( media-libs/opus )
  58         udev? ( >=virtual/udev-171 )
  59         vnc? ( >=net-libs/libvncserver-0.9.9 )
  60 "
  61 DEPEND="
  62         ${CDEPEND}
  63         alsa? ( >=media-libs/alsa-lib-1.0.13 )
  64         !headless? ( x11-libs/libXinerama )
  65         pam? ( sys-libs/pam )
  66         pax_kernel? ( sys-apps/elfix )
  67         pulseaudio? ( media-sound/pulseaudio )
  68         qt5? ( dev-qt/linguist-tools:5 )
  69         vboxwebsrv? ( net-libs/gsoap[-gnutls(-)] )
  70 "
  71 BDEPEND="
  72         ${PYTHON_DEPS}
  73         >=dev-util/kbuild-0.1.9998.3127
  74         >=dev-lang/yasm-0.6.2
  75         sys-devel/bin86
  76         sys-libs/libcap
  77         sys-power/iasl
  78         virtual/pkgconfig
  79         doc? (
  80                 app-text/docbook-sgml-dtd:4.4
  81                 dev-texlive/texlive-basic
  82                 dev-texlive/texlive-latex
  83                 dev-texlive/texlive-latexrecommended
  84                 dev-texlive/texlive-latexextra
  85                 dev-texlive/texlive-fontsrecommended
  86                 dev-texlive/texlive-fontsextra
  87         )
  88         java? ( >=virtual/jdk-1.6 )
  89 "
  90 RDEPEND="
  91         ${CDEPEND}
  92         java? ( >=virtual/jre-1.6 )
  93 "
  94
  95 QA_TEXTRELS_x86="usr/lib/virtualbox-ose/VBoxGuestPropSvc.so
  96         usr/lib/virtualbox/VBoxSDL.so
  97         usr/lib/virtualbox/VBoxSharedFolders.so
  98         usr/lib/virtualbox/VBoxDD2.so
  99         usr/lib/virtualbox/VBoxOGLrenderspu.so
 100         usr/lib/virtualbox/VBoxPython.so
 101         usr/lib/virtualbox/VBoxDD.so
 102         usr/lib/virtualbox/VBoxDDU.so
 103         usr/lib/virtualbox/VBoxREM64.so
 104         usr/lib/virtualbox/VBoxSharedClipboard.so
 105         usr/lib/virtualbox/VBoxHeadless.so
 106         usr/lib/virtualbox/VBoxRT.so
 107         usr/lib/virtualbox/VBoxREM.so
 108         usr/lib/virtualbox/VBoxSettings.so
 109         usr/lib/virtualbox/VBoxKeyboard.so
 110         usr/lib/virtualbox/VBoxSharedCrOpenGL.so
 111         usr/lib/virtualbox/VBoxVMM.so
 112         usr/lib/virtualbox/VirtualBox.so
 113         usr/lib/virtualbox/VBoxOGLhosterrorspu.so
 114         usr/lib/virtualbox/components/VBoxC.so
 115         usr/lib/virtualbox/components/VBoxSVCM.so
 116         usr/lib/virtualbox/components/VBoxDDU.so
 117         usr/lib/virtualbox/components/VBoxRT.so
 118         usr/lib/virtualbox/components/VBoxREM.so
 119         usr/lib/virtualbox/components/VBoxVMM.so
 120         usr/lib/virtualbox/VBoxREM32.so
 121         usr/lib/virtualbox/VBoxPython2_7.so
 122         usr/lib/virtualbox/VBoxXPCOMC.so
 123         usr/lib/virtualbox/VBoxOGLhostcrutil.so
 124         usr/lib/virtualbox/VBoxNetDHCP.so
 125         usr/lib/virtualbox/VBoxNetNAT.so"
 126
 127 S="${WORKDIR}/${MY_P}"
 128
 129 REQUIRED_USE="
 130         java? ( sdk )
 131         python? ( sdk )
 132         vboxwebsrv? ( java )
 133         ${PYTHON_REQUIRED_USE}
 134 "
 135
 136 pkg_pretend() {
 137         if ! use headless && ! use qt5 ; then
 138                 einfo "No USE=\"qt5\" selected, this build will not include any Qt frontend."
 139         elif use headless && use qt5 ; then
 140                 einfo "You selected USE=\"headless qt5\", defaulting to"
 141                 einfo "USE=\"headless\", this build will not include any X11/Qt frontend."
 142         fi
 143
 144         if ! use opengl ; then
 145                 einfo "No USE=\"opengl\" selected, this build will lack"
 146                 einfo "the OpenGL feature."
 147         fi
 148         if ! use python ; then
 149                 einfo "You have disabled the \"python\" USE flag. This will only"
 150                 einfo "disable the python bindings being installed."
 151         fi
 152 }
 153
 154 pkg_setup() {
 155         java-pkg-opt-2_pkg_setup
 156         python-single-r1_pkg_setup
 157
 158         tc-ld-disable-gold #bug 488176
 159         tc-export CC CXX LD AR RANLIB
 160         export HOST_CC="$(tc-getBUILD_CC)"
 161 }
 162
 163 src_prepare() {
 164         # Remove shipped binaries (kBuild,yasm), see bug #232775
 165         rm -r kBuild/bin tools || die
 166
 167         # Replace pointless GCC version check with something less stupid.
 168         # This is needed for the qt5 version check.
 169         sed -e 's@^check_gcc$@cc_maj="$(${CC} -dumpversion | cut -d. -f1)" ; cc_min="$(${CC} -dumpversion | cut -d. -f2)"@' \
 170                 -i configure || die
 171
 172         # Disable things unused or split into separate ebuilds
 173         sed -e "s@MY_LIBDIR@$(get_libdir)@" \
 174                 "${FILESDIR}"/${PN}-5-localconfig > LocalConfig.kmk || die
 175
 176         # Respect LDFLAGS
 177         sed -e "s@_LDFLAGS\.${ARCH}*.*=@& ${LDFLAGS}@g" \
 178                 -i Config.kmk src/libs/xpcom18a4/Config.kmk || die
 179
 180         # Do not use hard-coded ld (related to bug #488176)
 181         sed -e '/QUIET)ld /s@ld @$(LD) @' \
 182                 -i src/VBox/Devices/PC/ipxe/Makefile.kmk || die
 183
 184         # Use PAM only when pam USE flag is enbaled (bug #376531)
 185         if ! use pam ; then
 186                 elog "Disabling PAM removes the possibility to use the VRDP features."
 187                 sed -i 's@^.*VBOX_WITH_PAM@#VBOX_WITH_PAM@' Config.kmk || die
 188                 sed -i 's@\(.*/auth/Makefile.kmk.*\)@#\1@' \
 189                         src/VBox/HostServices/Makefile.kmk || die
 190         fi
 191
 192         # add correct java path
 193         if use java ; then
 194                 sed "s@/usr/lib/jvm/java-6-sun@$(java-config -O)@" \
 195                         -i "${S}"/Config.kmk || die
 196                 java-pkg-opt-2_src_prepare
 197         fi
 198
 199         # Only add nopie patch when we're on hardened
 200         if gcc-specs-pie ; then
 201                 eapply "${FILESDIR}/050_virtualbox-5.2.8-nopie.patch"
 202         fi
 203
 204         # Only add paxmark patch when we're on pax_kernel
 205         if use pax_kernel ; then
 206                 eapply "${FILESDIR}"/virtualbox-5.2.8-paxmark-bldprogs.patch
 207         fi
 208
 209         eapply "${WORKDIR}/patches"
 210
 211         eapply_user
 212 }
 213
 214 doecho() {
 215         echo "$@"
 216         "$@" || die
 217 }
 218
 219 src_configure() {
 220         local myconf=(
 221                 --with-gcc="$(tc-getCC)"
 222                 --with-g++="$(tc-getCXX)"
 223                 --disable-dbus
 224                 --disable-kmods
 225                 $(usex alsa '' --disable-alsa)
 226                 $(usex debug --build-debug '')
 227                 $(usex doc '' --disable-docs)
 228                 $(usex java '' --disable-java)
 229                 $(usex lvm '' --disable-devmapper)
 230                 $(usex opus '' --disable-libopus)
 231                 $(usex pulseaudio '' --disable-pulse)
 232                 $(usex python '' --disable-python)
 233                 $(usex vboxwebsrv --enable-webservice '')
 234                 $(usex vnc --enable-vnc '')
 235         )
 236         if ! use headless ; then
 237                 myconf+=(
 238                         $(usex opengl '' --disable-opengl)
 239                         $(usex qt5 '' --disable-qt)
 240                 )
 241         else
 242                 myconf+=(
 243                         --build-headless
 244                         --disable-opengl
 245                 )
 246         fi
 247         if use amd64 && ! has_multilib_profile ; then
 248                 myconf+=( --disable-vmmraw )
 249         fi
 250         # not an autoconf script
 251         doecho ./configure ${myconf[@]}
 252 }
 253
 254 src_compile() {
 255         source ./env.sh || die
 256
 257         # Force kBuild to respect C[XX]FLAGS and MAKEOPTS (bug #178529)
 258         MAKEJOBS=$(grep -Eo '(\-j|\-\-jobs)(=?|[[:space:]]*)[[:digit:]]+' <<< ${MAKEOPTS}) #'
 259         MAKELOAD=$(grep -Eo '(\-l|\-\-load-average)(=?|[[:space:]]*)[[:digit:]]+' <<< ${MAKEOPTS}) #'
 260         MAKEOPTS="${MAKEJOBS} ${MAKELOAD}"
 261         MAKE="kmk" emake \
 262                 VBOX_BUILD_PUBLISHER=_Gentoo \
 263                 TOOL_GCC3_CC="$(tc-getCC)" TOOL_GCC3_CXX="$(tc-getCXX)" \
 264                 TOOL_GCC3_AS="$(tc-getCC)" TOOL_GCC3_AR="$(tc-getAR)" \
 265                 TOOL_GCC3_LD="$(tc-getCXX)" TOOL_GCC3_LD_SYSMOD="$(tc-getLD)" \
 266                 TOOL_GCC3_CFLAGS="${CFLAGS}" TOOL_GCC3_CXXFLAGS="${CXXFLAGS}" \
 267                 VBOX_GCC_OPT="${CXXFLAGS}" \
 268                 TOOL_YASM_AS=yasm KBUILD_VERBOSE=2 \
 269                 all
 270 }
 271
 272 src_install() {
 273         cd "${S}"/out/linux.${ARCH}/$(usex debug debug release)/bin || die
 274
 275         local vbox_inst_path="/usr/$(get_libdir)/${PN}" each size ico icofile
 276
 277         vbox_inst() {
 278                 local binary="${1}"
 279                 local perms="${2:-0750}"
 280                 local path="${3:-${vbox_inst_path}}"
 281
 282                 [[ -n "${binary}" ]] || die "vbox_inst: No binary given!"
 283                 [[ ${perms} =~ ^[[:digit:]]+{4}$ ]] || die "vbox_inst: perms must consist of four digits."
 284
 285                 insinto ${path}
 286                 doins ${binary}
 287                 fowners root:vboxusers ${path}/${binary}
 288                 fperms ${perms} ${path}/${binary}
 289         }
 290
 291         # Create configuration files
 292         insinto /etc/vbox
 293         newins "${FILESDIR}/${PN}-4-config" vbox.cfg
 294
 295         # Set the correct libdir
 296         sed \
 297                 -e "s@MY_LIBDIR@$(get_libdir)@" \
 298                 -i "${ED}"/etc/vbox/vbox.cfg || die "vbox.cfg sed failed"
 299
 300         # Install the wrapper script
 301         exeinto ${vbox_inst_path}
 302         newexe "${FILESDIR}/${PN}-ose-6-wrapper" "VBox"
 303         fowners root:vboxusers ${vbox_inst_path}/VBox
 304         fperms 0750 ${vbox_inst_path}/VBox
 305
 306         # Install binaries and libraries
 307         insinto ${vbox_inst_path}
 308         doins -r components
 309
 310         for each in VBox{Autostart,BalloonCtrl,BugReport,CpuReport,ExtPackHelperApp,Manage,SVC,Tunctl,VMMPreload,XPCOMIPCD} *so *r0 iPxeBaseBin ; do
 311                 vbox_inst ${each}
 312         done
 313
 314         # These binaries need to be suid root.
 315         for each in VBox{Headless,Net{AdpCtl,DHCP,NAT}} ; do
 316                 vbox_inst ${each} 4750
 317         done
 318
 319         # Install EFI Firmware files (bug #320757)
 320         for each in VBoxEFI{32,64}.fd ; do
 321                 vbox_inst ${each} 0644
 322         done
 323
 324         # VBoxSVC and VBoxManage need to be pax-marked (bug #403453)
 325         # VBoxXPCOMIPCD (bug #524202)
 326         for each in VBox{Headless,Manage,SVC,XPCOMIPCD} ; do
 327                 pax-mark -m "${ED}"${vbox_inst_path}/${each}
 328         done
 329
 330         # Symlink binaries to the shipped wrapper
 331         for each in vbox{autostart,balloonctrl,bugreport,headless,manage} VBox{Autostart,BalloonCtrl,BugReport,Headless,Manage,VRDP} ; do
 332                 dosym ${vbox_inst_path}/VBox /usr/bin/${each}
 333         done
 334         dosym ${vbox_inst_path}/VBoxTunctl /usr/bin/VBoxTunctl
 335
 336         if use pam ; then
 337                 # VRDPAuth only works with this (bug #351949)
 338                 dosym VBoxAuth.so ${vbox_inst_path}/VRDPAuth.so
 339         fi
 340
 341         # set an env-variable for 3rd party tools
 342         echo -n "VBOX_APP_HOME=${vbox_inst_path}" > "${T}/90virtualbox"
 343         doenvd "${T}/90virtualbox"
 344
 345         if ! use headless ; then
 346                 vbox_inst rdesktop-vrdp
 347                 vbox_inst VBoxSDL 4750
 348                 pax-mark -m "${ED}"${vbox_inst_path}/VBoxSDL
 349
 350                 for each in vboxsdl VBoxSDL ; do
 351                         dosym ${vbox_inst_path}/VBox /usr/bin/${each}
 352                 done
 353
 354                 if use qt5 ; then
 355                         vbox_inst VirtualBox
 356                         vbox_inst VirtualBoxVM 4750
 357                         for each in VirtualBox{,VM} ; do
 358                                 pax-mark -m "${ED}"${vbox_inst_path}/${each}
 359                         done
 360
 361                         if use opengl ; then
 362                                 vbox_inst VBoxTestOGL
 363                                 pax-mark -m "${ED}"${vbox_inst_path}/VBoxTestOGL
 364                         fi
 365
 366                         for each in virtualbox{,vm} VirtualBox{,VM} ; do
 367                                 dosym ${vbox_inst_path}/VBox /usr/bin/${each}
 368                         done
 369
 370                         insinto /usr/share/${PN}
 371                         doins -r nls
 372                         doins -r UnattendedTemplates
 373
 374                         domenu ${PN}.desktop
 375                 fi
 376
 377                 pushd "${S}"/src/VBox/Artwork/OSE &>/dev/null || die
 378                 for size in 16 32 48 64 128 ; do
 379                         newicon -s ${size} ${PN}-${size}px.png ${PN}.png
 380                 done
 381                 newicon ${PN}-48px.png ${PN}.png
 382                 doicon -s scalable ${PN}.svg
 383                 popd &>/dev/null || die
 384                 pushd "${S}"/src/VBox/Artwork/other &>/dev/null || die
 385                 for size in 16 24 32 48 64 72 96 128 256 512 ; do
 386                         for ico in hdd ova ovf vbox{,-extpack} vdi vdh vmdk ; do
 387                                 icofile="${PN}-${ico}-${size}px.png"
 388                                 if [[ -f "${icofile}" ]] ; then
 389                                         newicon -s ${size} ${icofile} ${PN}-${ico}.png
 390                                 fi
 391                         done
 392                 done
 393                 popd &>/dev/null || die
 394         fi
 395
 396         if use lvm ; then
 397                 vbox_inst VBoxVolInfo 4750
 398                 dosym ${vbox_inst_path}/VBoxVolInfo /usr/bin/VBoxVolInfo
 399         fi
 400
 401         if use sdk ; then
 402                 insinto ${vbox_inst_path}
 403                 doins -r sdk
 404
 405                 if use java ; then
 406                         java-pkg_regjar "${ED}/${vbox_inst_path}/sdk/bindings/xpcom/java/vboxjxpcom.jar"
 407                         java-pkg_regso "${ED}/${vbox_inst_path}/libvboxjxpcom.so"
 408                 fi
 409         fi
 410
 411         if use udev ; then
 412                 # New way of handling USB device nodes for VBox (bug #356215)
 413                 local udevdir="$(get_udevdir)"
 414                 insinto ${udevdir}
 415                 doins VBoxCreateUSBNode.sh
 416                 fowners root:vboxusers ${udevdir}/VBoxCreateUSBNode.sh
 417                 fperms 0750 ${udevdir}/VBoxCreateUSBNode.sh
 418                 insinto ${udevdir}/rules.d
 419                 sed "s@%UDEVDIR%@${udevdir}@" "${FILESDIR}"/10-virtualbox.rules \
 420                         > "${T}"/10-virtualbox.rules || die
 421                 doins "${T}"/10-virtualbox.rules
 422         fi
 423
 424         if use vboxwebsrv ; then
 425                 vbox_inst vboxwebsrv
 426                 dosym ${vbox_inst_path}/VBox /usr/bin/vboxwebsrv
 427                 newinitd "${FILESDIR}"/vboxwebsrv-initd vboxwebsrv
 428                 newconfd "${FILESDIR}"/vboxwebsrv-confd vboxwebsrv
 429         fi
 430
 431         # Fix version string in extensions or else they don't get accepted
 432         # by the virtualbox host process (see bug #438930)
 433         find ExtensionPacks -type f -name "ExtPack.xml" -print0 \
 434                 | xargs --no-run-if-empty --null sed -i '/Version/s@_Gentoo@@' \
 435                 || die
 436
 437         local extensions_dir="${vbox_inst_path}/ExtensionPacks"
 438
 439         if use vnc ; then
 440                 insinto ${extensions_dir}
 441                 doins -r ExtensionPacks/VNC
 442         fi
 443
 444         if use dtrace ; then
 445                 insinto ${extensions_dir}
 446                 doins -r ExtensionPacks/Oracle_VBoxDTrace_Extension_Pack
 447         fi
 448
 449         if use doc ; then
 450                 dodoc UserManual.pdf
 451         fi
 452
 453         newtmpfiles "${FILESDIR}"/${PN}-vboxusb_tmpfilesd ${PN}-vboxusb.conf
 454 }
 455
 456 pkg_preinst() {
 457         xdg_pkg_preinst
 458 }
 459
 460 pkg_postinst() {
 461         xdg_pkg_postinst
 462
 463         if use udev ; then
 464                 udevadm control --reload-rules \
 465                         && udevadm trigger --subsystem-match=usb
 466         fi
 467
 468         tmpfiles_process /usr/lib/tmpfiles.d/virtualbox-vboxusb.conf
 469
 470         if ! use headless && use qt5 ; then
 471                 elog "To launch VirtualBox just type: \"virtualbox\"."
 472         fi
 473         elog "You must be in the vboxusers group to use VirtualBox."
 474         elog ""
 475         elog "The latest user manual is available for download at:"
 476         elog "http://download.virtualbox.org/virtualbox/${PV}/UserManual.pdf"
 477         elog ""
 478         elog "For advanced networking setups you should emerge:"
 479         elog "net-misc/bridge-utils and sys-apps/usermode-utilities"
 480         elog ""
 481         elog "Starting with version 4.0.0, ${PN} has USB-1 support."
 482         elog "For USB-2 support, PXE-boot ability and VRDP support please emerge"
 483         elog "  app-emulation/virtualbox-extpack-oracle"
 484         elog "package."
 485         elog "Starting with version 5.0.0, ${PN} no longer has the \"additions\" and"
 486         elog "the \"extension\" USE flag. For installation of the guest additions ISO"
 487         elog "image, please emerge"
 488         elog "  app-emulation/virtualbox-additions"
 489         elog "and for the USB2, USB3, VRDP and PXE boot ROM modules, please emerge"
 490         elog "  app-emulation/virtualbox-extpack-oracle"
 491         if ! use udev ; then
 492                 elog ""
 493                 elog "WARNING!"
 494                 elog "Without USE=udev, USB devices will likely not work in ${PN}."
 495         elif [[ -e "${ROOT}/etc/udev/rules.d/10-virtualbox.rules" ]] ; then
 496                 elog ""
 497                 elog "Please remove \"${ROOT}/etc/udev/rules.d/10-virtualbox.rules\""
 498                 elog "or else USB in ${PN} won't work."
 499         fi
 500 }
 501
 502 pkg_postrm() {
 503         xdg_pkg_postrm
 504 }