app-emulation/virtualbox/virtualbox-6.0.12.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python{2_7,3_{6,7}} )
   7 inherit desktop flag-o-matic java-pkg-opt-2 linux-info pax-utils python-single-r1 tmpfiles toolchain-funcs udev xdg
   8
   9 MY_PV="${PV/beta/BETA}"
  10 MY_PV="${MY_PV/rc/RC}"
  11 MY_P=VirtualBox-${MY_PV}
  12
  13 DESCRIPTION="Family of powerful x86 virtualization products for enterprise and home use"
  14 HOMEPAGE="https://www.virtualbox.org/"
  15 SRC_URI="https://download.virtualbox.org/virtualbox/${MY_PV}/${MY_P}.tar.bz2
  16         https://dev.gentoo.org/~polynomial-c/${PN}/patchsets/${PN}-6.0.0_beta2-patches-01.tar.xz"
  17
  18 LICENSE="GPL-2 dtrace? ( CDDL )"
  19 SLOT="0"
  20 [[ "${PV}" == *_beta* ]] || [[ "${PV}" == *_rc* ]] || \
  21 KEYWORDS="~amd64 ~x86"
  22 IUSE="alsa debug doc dtrace headless java libressl lvm +opus pam pax_kernel pulseaudio +opengl python +qt5 +sdk +udev vboxwebsrv vnc"
  23
  24 CDEPEND="
  25         ${PYTHON_DEPS}
  26         !app-emulation/virtualbox-bin
  27         ~app-emulation/virtualbox-modules-${PV}
  28         dev-libs/libIDL
  29         >=dev-libs/libxslt-1.1.19
  30         net-misc/curl
  31         dev-libs/libxml2
  32         media-libs/libpng:0=
  33         media-libs/libvpx:0=
  34         sys-libs/zlib:=
  35         !headless? (
  36                 media-libs/libsdl:0[X,video]
  37                 x11-libs/libX11
  38                 x11-libs/libxcb:=
  39                 x11-libs/libXcursor
  40                 x11-libs/libXext
  41                 x11-libs/libXmu
  42                 x11-libs/libXt
  43                 opengl? ( virtual/opengl media-libs/freeglut )
  44                 qt5? (
  45                         dev-qt/qtcore:5
  46                         dev-qt/qtgui:5
  47                         dev-qt/qtprintsupport:5
  48                         dev-qt/qtwidgets:5
  49                         dev-qt/qtx11extras:5
  50                         opengl? ( dev-qt/qtopengl:5 )
  51                         x11-libs/libXinerama
  52                 )
  53         )
  54         libressl? ( dev-libs/libressl:= )
  55         !libressl? ( dev-libs/openssl:0= )
  56         lvm? ( sys-fs/lvm2 )
  57         opus? ( media-libs/opus )
  58         udev? ( >=virtual/udev-171 )
  59         vnc? ( >=net-libs/libvncserver-0.9.9 )
  60 "
  61 DEPEND="
  62         ${CDEPEND}
  63         alsa? ( >=media-libs/alsa-lib-1.0.13 )
  64         !headless? ( x11-libs/libXinerama )
  65         pam? ( sys-libs/pam )
  66         pax_kernel? ( sys-apps/elfix )
  67         pulseaudio? ( media-sound/pulseaudio )
  68         qt5? ( dev-qt/linguist-tools:5 )
  69         vboxwebsrv? ( net-libs/gsoap[-gnutls(-)] )
  70 "
  71 BDEPEND="
  72         ${PYTHON_DEPS}
  73         >=dev-util/kbuild-0.1.9998.3127
  74         >=dev-lang/yasm-0.6.2
  75         sys-devel/bin86
  76         sys-libs/libcap
  77         sys-power/iasl
  78         virtual/pkgconfig
  79         doc? (
  80                 app-text/docbook-sgml-dtd:4.4
  81                 dev-texlive/texlive-basic
  82                 dev-texlive/texlive-latex
  83                 dev-texlive/texlive-latexrecommended
  84                 dev-texlive/texlive-latexextra
  85                 dev-texlive/texlive-fontsrecommended
  86                 dev-texlive/texlive-fontsextra
  87         )
  88         java? ( >=virtual/jdk-1.6 )
  89 "
  90 RDEPEND="
  91         ${CDEPEND}
  92         java? ( >=virtual/jre-1.6 )
  93 "
  94
  95 QA_TEXTRELS_x86="usr/lib/virtualbox-ose/VBoxGuestPropSvc.so
  96         usr/lib/virtualbox/VBoxSDL.so
  97         usr/lib/virtualbox/VBoxSharedFolders.so
  98         usr/lib/virtualbox/VBoxDD2.so
  99         usr/lib/virtualbox/VBoxOGLrenderspu.so
 100         usr/lib/virtualbox/VBoxPython.so
 101         usr/lib/virtualbox/VBoxDD.so
 102         usr/lib/virtualbox/VBoxDDU.so
 103         usr/lib/virtualbox/VBoxREM64.so
 104         usr/lib/virtualbox/VBoxSharedClipboard.so
 105         usr/lib/virtualbox/VBoxHeadless.so
 106         usr/lib/virtualbox/VBoxRT.so
 107         usr/lib/virtualbox/VBoxREM.so
 108         usr/lib/virtualbox/VBoxSettings.so
 109         usr/lib/virtualbox/VBoxKeyboard.so
 110         usr/lib/virtualbox/VBoxSharedCrOpenGL.so
 111         usr/lib/virtualbox/VBoxVMM.so
 112         usr/lib/virtualbox/VirtualBox.so
 113         usr/lib/virtualbox/VBoxOGLhosterrorspu.so
 114         usr/lib/virtualbox/components/VBoxC.so
 115         usr/lib/virtualbox/components/VBoxSVCM.so
 116         usr/lib/virtualbox/components/VBoxDDU.so
 117         usr/lib/virtualbox/components/VBoxRT.so
 118         usr/lib/virtualbox/components/VBoxREM.so
 119         usr/lib/virtualbox/components/VBoxVMM.so
 120         usr/lib/virtualbox/VBoxREM32.so
 121         usr/lib/virtualbox/VBoxPython2_7.so
 122         usr/lib/virtualbox/VBoxXPCOMC.so
 123         usr/lib/virtualbox/VBoxOGLhostcrutil.so
 124         usr/lib/virtualbox/VBoxNetDHCP.so
 125         usr/lib/virtualbox/VBoxNetNAT.so"
 126
 127 S="${WORKDIR}/${MY_P}"
 128
 129 REQUIRED_USE="
 130         java? ( sdk )
 131         python? ( sdk )
 132         vboxwebsrv? ( java )
 133         ${PYTHON_REQUIRED_USE}
 134 "
 135
 136 pkg_pretend() {
 137         if ! use headless && ! use qt5 ; then
 138                 einfo "No USE=\"qt5\" selected, this build will not include any Qt frontend."
 139         elif use headless && use qt5 ; then
 140                 einfo "You selected USE=\"headless qt5\", defaulting to"
 141                 einfo "USE=\"headless\", this build will not include any X11/Qt frontend."
 142         fi
 143
 144         if ! use opengl ; then
 145                 einfo "No USE=\"opengl\" selected, this build will lack"
 146                 einfo "the OpenGL feature."
 147         fi
 148         if ! use python ; then
 149                 einfo "You have disabled the \"python\" USE flag. This will only"
 150                 einfo "disable the python bindings being installed."
 151         fi
 152 }
 153
 154 pkg_setup() {
 155         java-pkg-opt-2_pkg_setup
 156         python-single-r1_pkg_setup
 157
 158         tc-ld-disable-gold #bug 488176
 159         tc-export CC CXX LD AR RANLIB
 160         export HOST_CC="$(tc-getBUILD_CC)"
 161 }
 162
 163 src_prepare() {
 164         # Remove shipped binaries (kBuild,yasm), see bug #232775
 165         rm -r kBuild/bin tools || die
 166
 167         # Replace pointless GCC version check with something less stupid.
 168         # This is needed for the qt5 version check.
 169         sed -e 's@^check_gcc$@cc_maj="$(gcc -dumpversion | cut -d. -f1)" ; cc_min="$(gcc -dumpversion | cut -d. -f2)"@' \
 170                 -i configure || die
 171
 172         # Disable things unused or split into separate ebuilds
 173         sed -e "s@MY_LIBDIR@$(get_libdir)@" \
 174                 "${FILESDIR}"/${PN}-5-localconfig > LocalConfig.kmk || die
 175
 176         # Respect LDFLAGS
 177         sed -e "s@_LDFLAGS\.${ARCH}*.*=@& ${LDFLAGS}@g" \
 178                 -i Config.kmk src/libs/xpcom18a4/Config.kmk || die
 179
 180         # Do not use hard-coded ld (related to bug #488176)
 181         sed -e '/QUIET)ld /s@ld @$(LD) @' \
 182                 -i src/VBox/Devices/PC/ipxe/Makefile.kmk || die
 183
 184         # Use PAM only when pam USE flag is enbaled (bug #376531)
 185         if ! use pam ; then
 186                 elog "Disabling PAM removes the possibility to use the VRDP features."
 187                 sed -i 's@^.*VBOX_WITH_PAM@#VBOX_WITH_PAM@' Config.kmk || die
 188                 sed -i 's@\(.*/auth/Makefile.kmk.*\)@#\1@' \
 189                         src/VBox/HostServices/Makefile.kmk || die
 190         fi
 191
 192         # add correct java path
 193         if use java ; then
 194                 sed "s@/usr/lib/jvm/java-6-sun@$(java-config -O)@" \
 195                         -i "${S}"/Config.kmk || die
 196                 java-pkg-opt-2_src_prepare
 197         fi
 198
 199         # Only add nopie patch when we're on hardened
 200         if gcc-specs-pie ; then
 201                 eapply "${FILESDIR}/050_virtualbox-5.2.8-nopie.patch"
 202         fi
 203
 204         # Only add paxmark patch when we're on pax_kernel
 205         if use pax_kernel ; then
 206                 eapply "${FILESDIR}"/virtualbox-5.2.8-paxmark-bldprogs.patch
 207         fi
 208
 209         rm "${WORKDIR}/patches/010_virtualbox-5.2.12-qt511.patch" || die
 210         eapply "${WORKDIR}/patches"
 211
 212         eapply_user
 213 }
 214
 215 doecho() {
 216         echo "$@"
 217         "$@" || die
 218 }
 219
 220 src_configure() {
 221         local myconf=(
 222                 --with-gcc="$(tc-getCC)"
 223                 --with-g++="$(tc-getCXX)"
 224                 --disable-dbus
 225                 --disable-kmods
 226                 $(usex alsa '' --disable-alsa)
 227                 $(usex debug --build-debug '')
 228                 $(usex doc '' --disable-docs)
 229                 $(usex java '' --disable-java)
 230                 $(usex lvm '' --disable-devmapper)
 231                 $(usex opus '' --disable-libopus)
 232                 $(usex pulseaudio '' --disable-pulse)
 233                 $(usex python '' --disable-python)
 234                 $(usex vboxwebsrv --enable-webservice '')
 235                 $(usex vnc --enable-vnc '')
 236         )
 237         if ! use headless ; then
 238                 myconf+=(
 239                         $(usex opengl '' --disable-opengl)
 240                         $(usex qt5 '' --disable-qt)
 241                 )
 242         else
 243                 myconf+=(
 244                         --build-headless
 245                         --disable-opengl
 246                 )
 247         fi
 248         if use amd64 && ! has_multilib_profile ; then
 249                 myconf+=( --disable-vmmraw )
 250         fi
 251         # not an autoconf script
 252         doecho ./configure ${myconf[@]}
 253 }
 254
 255 src_compile() {
 256         source ./env.sh || die
 257
 258         # Force kBuild to respect C[XX]FLAGS and MAKEOPTS (bug #178529)
 259         MAKEJOBS=$(grep -Eo '(\-j|\-\-jobs)(=?|[[:space:]]*)[[:digit:]]+' <<< ${MAKEOPTS}) #'
 260         MAKELOAD=$(grep -Eo '(\-l|\-\-load-average)(=?|[[:space:]]*)[[:digit:]]+' <<< ${MAKEOPTS}) #'
 261         MAKEOPTS="${MAKEJOBS} ${MAKELOAD}"
 262         MAKE="kmk" emake \
 263                 VBOX_BUILD_PUBLISHER=_Gentoo \
 264                 TOOL_GCC3_CC="$(tc-getCC)" TOOL_GCC3_CXX="$(tc-getCXX)" \
 265                 TOOL_GCC3_AS="$(tc-getCC)" TOOL_GCC3_AR="$(tc-getAR)" \
 266                 TOOL_GCC3_LD="$(tc-getCXX)" TOOL_GCC3_LD_SYSMOD="$(tc-getLD)" \
 267                 TOOL_GCC3_CFLAGS="${CFLAGS}" TOOL_GCC3_CXXFLAGS="${CXXFLAGS}" \
 268                 VBOX_GCC_OPT="${CXXFLAGS}" \
 269                 TOOL_YASM_AS=yasm KBUILD_VERBOSE=2 \
 270                 all
 271 }
 272
 273 src_install() {
 274         cd "${S}"/out/linux.${ARCH}/$(usex debug debug release)/bin || die
 275
 276         local vbox_inst_path="/usr/$(get_libdir)/${PN}" each size ico icofile
 277
 278         vbox_inst() {
 279                 local binary="${1}"
 280                 local perms="${2:-0750}"
 281                 local path="${3:-${vbox_inst_path}}"
 282
 283                 [[ -n "${binary}" ]] || die "vbox_inst: No binary given!"
 284                 [[ ${perms} =~ ^[[:digit:]]+{4}$ ]] || die "vbox_inst: perms must consist of four digits."
 285
 286                 insinto ${path}
 287                 doins ${binary}
 288                 fowners root:vboxusers ${path}/${binary}
 289                 fperms ${perms} ${path}/${binary}
 290         }
 291
 292         # Create configuration files
 293         insinto /etc/vbox
 294         newins "${FILESDIR}/${PN}-4-config" vbox.cfg
 295
 296         # Set the correct libdir
 297         sed \
 298                 -e "s@MY_LIBDIR@$(get_libdir)@" \
 299                 -i "${ED}"/etc/vbox/vbox.cfg || die "vbox.cfg sed failed"
 300
 301         # Install the wrapper script
 302         exeinto ${vbox_inst_path}
 303         newexe "${FILESDIR}/${PN}-ose-6-wrapper" "VBox"
 304         fowners root:vboxusers ${vbox_inst_path}/VBox
 305         fperms 0750 ${vbox_inst_path}/VBox
 306
 307         # Install binaries and libraries
 308         insinto ${vbox_inst_path}
 309         doins -r components
 310
 311         # *.rc files for x86_64 are only available on multilib systems
 312         local rcfiles="*.rc"
 313         if use amd64 && ! has_multilib_profile ; then
 314                 rcfiles=""
 315         fi
 316         for each in VBox{Autostart,BalloonCtrl,BugReport,CpuReport,ExtPackHelperApp,Manage,SVC,Tunctl,VMMPreload,XPCOMIPCD} *so *r0 ${rcfiles} iPxeBaseBin ; do
 317                 vbox_inst ${each}
 318         done
 319
 320         # These binaries need to be suid root.
 321         for each in VBox{Headless,Net{AdpCtl,DHCP,NAT}} ; do
 322                 vbox_inst ${each} 4750
 323         done
 324
 325         # Install EFI Firmware files (bug #320757)
 326         for each in VBoxEFI{32,64}.fd ; do
 327                 vbox_inst ${each} 0644
 328         done
 329
 330         # VBoxSVC and VBoxManage need to be pax-marked (bug #403453)
 331         # VBoxXPCOMIPCD (bug #524202)
 332         for each in VBox{Headless,Manage,SVC,XPCOMIPCD} ; do
 333                 pax-mark -m "${ED}"${vbox_inst_path}/${each}
 334         done
 335
 336         # Symlink binaries to the shipped wrapper
 337         for each in vbox{autostart,balloonctrl,bugreport,headless,manage} VBox{Autostart,BalloonCtrl,BugReport,Headless,Manage,VRDP} ; do
 338                 dosym ${vbox_inst_path}/VBox /usr/bin/${each}
 339         done
 340         dosym ${vbox_inst_path}/VBoxTunctl /usr/bin/VBoxTunctl
 341
 342         if use pam ; then
 343                 # VRDPAuth only works with this (bug #351949)
 344                 dosym VBoxAuth.so ${vbox_inst_path}/VRDPAuth.so
 345         fi
 346
 347         # set an env-variable for 3rd party tools
 348         echo -n "VBOX_APP_HOME=${vbox_inst_path}" > "${T}/90virtualbox"
 349         doenvd "${T}/90virtualbox"
 350
 351         if ! use headless ; then
 352                 vbox_inst rdesktop-vrdp
 353                 vbox_inst VBoxSDL 4750
 354                 pax-mark -m "${ED}"${vbox_inst_path}/VBoxSDL
 355
 356                 for each in vboxsdl VBoxSDL ; do
 357                         dosym ${vbox_inst_path}/VBox /usr/bin/${each}
 358                 done
 359
 360                 if use qt5 ; then
 361                         vbox_inst VirtualBox
 362                         vbox_inst VirtualBoxVM 4750
 363                         for each in VirtualBox{,VM} ; do
 364                                 pax-mark -m "${ED}"${vbox_inst_path}/${each}
 365                         done
 366
 367                         if use opengl ; then
 368                                 vbox_inst VBoxTestOGL
 369                                 pax-mark -m "${ED}"${vbox_inst_path}/VBoxTestOGL
 370                         fi
 371
 372                         for each in virtualbox{,vm} VirtualBox{,VM} ; do
 373                                 dosym ${vbox_inst_path}/VBox /usr/bin/${each}
 374                         done
 375
 376                         insinto /usr/share/${PN}
 377                         doins -r nls
 378                         doins -r UnattendedTemplates
 379
 380                         domenu ${PN}.desktop
 381                 fi
 382
 383                 pushd "${S}"/src/VBox/Artwork/OSE &>/dev/null || die
 384                 for size in 16 32 48 64 128 ; do
 385                         newicon -s ${size} ${PN}-${size}px.png ${PN}.png
 386                 done
 387                 newicon ${PN}-48px.png ${PN}.png
 388                 doicon -s scalable ${PN}.svg
 389                 popd &>/dev/null || die
 390                 pushd "${S}"/src/VBox/Artwork/other &>/dev/null || die
 391                 for size in 16 24 32 48 64 72 96 128 256 512 ; do
 392                         for ico in hdd ova ovf vbox{,-extpack} vdi vdh vmdk ; do
 393                                 icofile="${PN}-${ico}-${size}px.png"
 394                                 if [[ -f "${icofile}" ]] ; then
 395                                         newicon -s ${size} ${icofile} ${PN}-${ico}.png
 396                                 fi
 397                         done
 398                 done
 399                 popd &>/dev/null || die
 400         fi
 401
 402         if use lvm ; then
 403                 vbox_inst VBoxVolInfo 4750
 404                 dosym ${vbox_inst_path}/VBoxVolInfo /usr/bin/VBoxVolInfo
 405         fi
 406
 407         if use sdk ; then
 408                 insinto ${vbox_inst_path}
 409                 doins -r sdk
 410
 411                 if use java ; then
 412                         java-pkg_regjar "${ED}/${vbox_inst_path}/sdk/bindings/xpcom/java/vboxjxpcom.jar"
 413                         java-pkg_regso "${ED}/${vbox_inst_path}/libvboxjxpcom.so"
 414                 fi
 415         fi
 416
 417         if use udev ; then
 418                 # New way of handling USB device nodes for VBox (bug #356215)
 419                 local udevdir="$(get_udevdir)"
 420                 insinto ${udevdir}
 421                 doins VBoxCreateUSBNode.sh
 422                 fowners root:vboxusers ${udevdir}/VBoxCreateUSBNode.sh
 423                 fperms 0750 ${udevdir}/VBoxCreateUSBNode.sh
 424                 insinto ${udevdir}/rules.d
 425                 sed "s@%UDEVDIR%@${udevdir}@" "${FILESDIR}"/10-virtualbox.rules \
 426                         > "${T}"/10-virtualbox.rules || die
 427                 doins "${T}"/10-virtualbox.rules
 428         fi
 429
 430         if use vboxwebsrv ; then
 431                 vbox_inst vboxwebsrv
 432                 dosym ${vbox_inst_path}/VBox /usr/bin/vboxwebsrv
 433                 newinitd "${FILESDIR}"/vboxwebsrv-initd vboxwebsrv
 434                 newconfd "${FILESDIR}"/vboxwebsrv-confd vboxwebsrv
 435         fi
 436
 437         # Fix version string in extensions or else they don't get accepted
 438         # by the virtualbox host process (see bug #438930)
 439         find ExtensionPacks -type f -name "ExtPack.xml" -print0 \
 440                 | xargs --no-run-if-empty --null sed -i '/Version/s@_Gentoo@@' \
 441                 || die
 442
 443         local extensions_dir="${vbox_inst_path}/ExtensionPacks"
 444
 445         if use vnc ; then
 446                 insinto ${extensions_dir}
 447                 doins -r ExtensionPacks/VNC
 448         fi
 449
 450         if use dtrace ; then
 451                 insinto ${extensions_dir}
 452                 doins -r ExtensionPacks/Oracle_VBoxDTrace_Extension_Pack
 453         fi
 454
 455         if use doc ; then
 456                 dodoc UserManual.pdf
 457         fi
 458
 459         newtmpfiles "${FILESDIR}"/${PN}-vboxusb_tmpfilesd ${PN}-vboxusb.conf
 460 }
 461
 462 pkg_preinst() {
 463         xdg_pkg_preinst
 464 }
 465
 466 pkg_postinst() {
 467         xdg_pkg_postinst
 468
 469         if use udev ; then
 470                 udevadm control --reload-rules \
 471                         && udevadm trigger --subsystem-match=usb
 472         fi
 473
 474         tmpfiles_process /usr/lib/tmpfiles.d/virtualbox-vboxusb.conf
 475
 476         if ! use headless && use qt5 ; then
 477                 elog "To launch VirtualBox just type: \"virtualbox\"."
 478         fi
 479         elog "You must be in the vboxusers group to use VirtualBox."
 480         elog ""
 481         elog "The latest user manual is available for download at:"
 482         elog "http://download.virtualbox.org/virtualbox/${PV}/UserManual.pdf"
 483         elog ""
 484         elog "For advanced networking setups you should emerge:"
 485         elog "net-misc/bridge-utils and sys-apps/usermode-utilities"
 486         elog ""
 487         elog "Starting with version 4.0.0, ${PN} has USB-1 support."
 488         elog "For USB-2 support, PXE-boot ability and VRDP support please emerge"
 489         elog "  app-emulation/virtualbox-extpack-oracle"
 490         elog "package."
 491         elog "Starting with version 5.0.0, ${PN} no longer has the \"additions\" and"
 492         elog "the \"extension\" USE flag. For installation of the guest additions ISO"
 493         elog "image, please emerge"
 494         elog "  app-emulation/virtualbox-additions"
 495         elog "and for the USB2, USB3, VRDP and PXE boot ROM modules, please emerge"
 496         elog "  app-emulation/virtualbox-extpack-oracle"
 497         if ! use udev ; then
 498                 elog ""
 499                 elog "WARNING!"
 500                 elog "Without USE=udev, USB devices will likely not work in ${PN}."
 501         elif [[ -e "${ROOT}/etc/udev/rules.d/10-virtualbox.rules" ]] ; then
 502                 elog ""
 503                 elog "Please remove \"${ROOT}/etc/udev/rules.d/10-virtualbox.rules\""
 504                 elog "or else USB in ${PN} won't work."
 505         fi
 506 }
 507
 508 pkg_postrm() {
 509         xdg_pkg_postrm
 510 }