app-emulation/ganeti/ganeti-2.17.0_beta1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 PYTHON_COMPAT=(python2_7)
   6 PYTHON_REQ_USE="ipv6(+)?"
   7
   8 inherit user autotools bash-completion-r1 python-single-r1 versionator
   9
  10 MY_PV="${PV/_rc/~rc}"
  11 MY_PV="${MY_PV/_beta/~beta}"
  12 MY_P="${PN}-${MY_PV}"
  13 SERIES="$(get_version_component_range 1-2)"
  14
  15 if [[ ${PV} =~ [9]{4,} ]] ; then
  16         EGIT_REPO_URI="git://git.ganeti.org/ganeti.git"
  17         inherit git-2
  18         KEYWORDS=""
  19         PATCHES=()
  20 else
  21         DEBIAN_PV='2.16.0~rc1'
  22         DEBIAN_PATCH=1
  23         SRC_URI="http://downloads.ganeti.org/releases/${SERIES}/${MY_P}.tar.gz"
  24         [[ -n "${DEBIAN_PATCH}" ]] && SRC_URI="${SRC_URI}
  25           mirror://debian/pool/main/${PN:0:1}/${PN}/${PN}_${DEBIAN_PV}-${DEBIAN_PATCH}.debian.tar.xz
  26         "
  27         KEYWORDS="~amd64 ~x86"
  28         PATCHES=(
  29           "${WORKDIR}"/debian/patches/do-not-backup-export-dir.patch
  30           "${WORKDIR}"/debian/patches/Makefile.am-use-C.UTF-8
  31           #"${WORKDIR}"/debian/patches/relax-deps # Ported manually
  32           "${WORKDIR}"/debian/patches/zlib-0.6-compatibility
  33           "${WORKDIR}"/debian/patches/fix_FTBFS_with_sphinx-1.3.5
  34           #"${WORKDIR}"/debian/patches/fix_ftbfs_with_sphinx_1.4 # ported manually
  35         )
  36 fi
  37
  38 DESCRIPTION="Ganeti is a virtual server management software tool"
  39 HOMEPAGE="http://www.ganeti.org/"
  40
  41 LICENSE="GPL-2"
  42 SLOT="0"
  43 IUSE="drbd experimental haskell-daemons htools ipv6 kvm lxc monitoring multiple-users rbd syslog test xen restricted-commands"
  44 RESTRICT="!test? ( test )"
  45
  46 REQUIRED_USE="|| ( kvm xen lxc )
  47         test? ( ipv6 )
  48         kvm? ( || ( amd64 x86 ) )
  49         ${PYTHON_REQUIRED_USE}"
  50
  51 USER_PREFIX="${GANETI_USER_PREFIX:-"gnt-"}"
  52 GROUP_PREFIX="${GANETI_GROUP_PREFIX:-"${USER_PREFIX}"}"
  53
  54 DEPEND="
  55         dev-libs/openssl:0
  56         dev-python/paramiko[${PYTHON_USEDEP}]
  57         dev-python/pyopenssl[${PYTHON_USEDEP}]
  58         dev-python/simplejson[${PYTHON_USEDEP}]
  59         dev-python/pyparsing[${PYTHON_USEDEP}]
  60         dev-python/pyinotify[${PYTHON_USEDEP}]
  61         dev-python/pycurl[${PYTHON_USEDEP}]
  62         dev-python/ipaddr[${PYTHON_USEDEP}]
  63         dev-python/bitarray[${PYTHON_USEDEP}]
  64         dev-python/docutils[${PYTHON_USEDEP}]
  65         dev-python/fdsend[${PYTHON_USEDEP}]
  66         || (
  67                 net-misc/iputils[arping]
  68                 net-analyzer/arping
  69         )
  70         net-analyzer/fping
  71         net-misc/bridge-utils
  72         net-misc/curl[ssl]
  73         net-misc/openssh
  74         net-misc/socat
  75         sys-apps/iproute2
  76         sys-fs/lvm2
  77         >=sys-apps/baselayout-2.0
  78         dev-lang/ghc:0=
  79         dev-haskell/cabal:0=
  80         dev-haskell/cabal-install:0=
  81         >=dev-haskell/mtl-2.1.1:0=
  82         >=dev-haskell/old-time-1.1.0.0:0=
  83         >=dev-haskell/random-1.0.1.1:0=
  84         haskell-daemons? ( >=dev-haskell/text-0.11.1.13:0= )
  85         >=dev-haskell/transformers-0.3.0.0:0=
  86
  87         >=dev-haskell/attoparsec-0.10.1.1:0=
  88         <dev-haskell/attoparsec-0.14:0
  89         >=dev-haskell/base64-bytestring-1.0.0.1:0=
  90         <dev-haskell/base64-bytestring-1.1:0=
  91         >=dev-haskell/crypto-4.2.4:0=
  92         <dev-haskell/crypto-4.3:0=
  93         >=dev-haskell/curl-1.3.7:0=
  94         <dev-haskell/curl-1.4:0=
  95         >=dev-haskell/hinotify-0.3.2:0=
  96         <dev-haskell/hinotify-0.4:0=
  97         >=dev-haskell/hslogger-1.1.4:0=
  98         <dev-haskell/hslogger-1.3:0=
  99         >=dev-haskell/json-0.5:0=
 100         >=dev-haskell/lens-3.10:0=
 101         >=dev-haskell/lifted-base-0.2.0.3:0=
 102         <dev-haskell/lifted-base-0.3:0=
 103         >=dev-haskell/monad-control-0.3.1.3:0=
 104         <dev-haskell/monad-control-1.1:0=
 105         >=dev-haskell/network-2.3.0.13:0=
 106         <dev-haskell/network-2.7:0=
 107         >=dev-haskell/parallel-3.2.0.2:3=
 108         <dev-haskell/parallel-3.3:3=
 109         >=dev-haskell/temporary-1.1.2.3:0=
 110         <dev-haskell/temporary-1.3:0=
 111         >=dev-haskell/regex-pcre-0.94.2:0=
 112         <dev-haskell/regex-pcre-0.95:0=
 113         >=dev-haskell/transformers-base-0.4.1:0=
 114         <dev-haskell/transformers-base-0.5:0=
 115         >=dev-haskell/utf8-string-0.3.7:0=
 116         >=dev-haskell/zlib-0.5.3.3:0=
 117         <dev-haskell/zlib-0.7:0=
 118
 119         >=dev-haskell/psqueue-1.1:0=
 120         <dev-haskell/psqueue-1.2:0=
 121         >=dev-haskell/snap-core-0.8.1:0=
 122         <dev-haskell/snap-core-0.10:0=
 123         >=dev-haskell/snap-server-0.8.1:0=
 124         <dev-haskell/snap-server-0.10:0=
 125         >=dev-haskell/case-insensitive-0.4.0.1
 126
 127         dev-haskell/vector:0=
 128         xen? ( >=app-emulation/xen-3.0 )
 129         kvm? (
 130                 dev-python/psutil
 131                 app-emulation/qemu
 132         )
 133         lxc? ( app-emulation/lxc )
 134         drbd? ( sys-cluster/drbd-utils )
 135         rbd? ( sys-cluster/ceph )
 136         ipv6? ( net-misc/ndisc6 )
 137         ${PYTHON_DEPS}"
 138 RDEPEND="${DEPEND}
 139         !app-emulation/ganeti-htools"
 140 DEPEND+="
 141         sys-devel/m4
 142         app-text/pandoc
 143         <=dev-python/sphinx-1.3.5[${PYTHON_USEDEP}]
 144         media-fonts/urw-fonts
 145         media-gfx/graphviz
 146         >=dev-haskell/test-framework-0.6:0=
 147         <dev-haskell/test-framework-0.9:0=
 148         >=dev-haskell/test-framework-hunit-0.2.7:0=
 149         <dev-haskell/test-framework-hunit-0.4:0=
 150         >=dev-haskell/test-framework-quickcheck2-0.2.12.1:0=
 151         <dev-haskell/test-framework-quickcheck2-0.4:0=
 152         test? (
 153                 dev-python/mock
 154                 dev-python/pyyaml
 155                 dev-haskell/haddock:0=
 156                 >=dev-haskell/hunit-1.2.4.2:0=
 157                 <dev-haskell/hunit-1.3:0=
 158                 >=dev-haskell/quickcheck-2.4.2:2=
 159                 <dev-haskell/quickcheck-2.8.3:2=
 160                 sys-apps/fakeroot
 161                 >=net-misc/socat-1.7
 162                 dev-util/shelltestrunner
 163         )"
 164
 165 PATCHES+=(
 166         "${FILESDIR}/${PN}-2.12-start-stop-daemon-args.patch"
 167         "${FILESDIR}/${PN}-2.11-add-pgrep.patch"
 168         "${FILESDIR}/${PN}-2.15-daemon-util.patch"
 169         "${FILESDIR}/${PN}-2.9-disable-root-tests.patch"
 170         "${FILESDIR}/${PN}-2.9-skip-cli-test.patch"
 171         "${FILESDIR}/${PN}-2.10-rundir.patch"
 172         "${FILESDIR}/${PN}-2.12-qemu-enable-kvm.patch"
 173         "${FILESDIR}/${PN}-2.11-tests.patch"
 174         "${FILESDIR}/${PN}-lockdir.patch"
 175         "${FILESDIR}/${PN}-2.11-dont-nest-libdir.patch"
 176         "${FILESDIR}/${PN}-2.11-dont-print-man-help.patch"
 177         "${FILESDIR}/${PN}-2.11-daemon-util-tests.patch"
 178         "${FILESDIR}/${PN}-2.13-process_unittest.patch"
 179         "${FILESDIR}/${PN}-2.15-python-mock.patch"
 180         "${FILESDIR}/${PN}-2.15.2-remove-sandbox-failing-tests.patch"
 181         "${FILESDIR}/${PN}-2.16-noded-must-run-as-root.patch"
 182         "${FILESDIR}/${PN}-2.16-kvmd-run-as-daemon-user.patch"
 183         "${FILESDIR}/${PN}-2.15-dont-invert-return-values-for-man-warnings.patch"
 184         "${FILESDIR}/fix_ftbfs_with_sphinx_1.4"
 185         "${FILESDIR}/${PN}-2.17-relax-deps.patch"
 186 )
 187
 188 S="${WORKDIR}/${MY_P}"
 189
 190 QA_WX_LOAD="
 191         usr/lib*/${PN}/${SERIES}/usr/sbin/ganeti-*d
 192         usr/lib*/${PN}/${SERIES}/usr/bin/htools
 193 "
 194
 195 pkg_setup () {
 196         local user
 197         python-single-r1_pkg_setup
 198
 199         if use multiple-users; then
 200                 for user in gnt-{masterd,confd,luxid,rapi,daemons,admin}; do
 201                         enewgroup ${user}
 202                         enewuser ${user} -1 -1 -1 ${user}
 203                 done
 204         fi
 205 }
 206
 207 src_prepare() {
 208         local testfile
 209         if has_version '>=dev-lang/ghc-7.10'; then
 210                 # Breaks the build on 7.8
 211                 PATCHES+=(
 212                         "${WORKDIR}"/debian/patches/ghc-7.10-compatibility.patch
 213                 )
 214         fi
 215         if use experimental; then
 216                 ewarn "Experimental patches have been applied! RPC between daemons with different patches applied may cause breakage!"
 217                 PATCHES+=(
 218                         # QEMU Agent accepted upstream for 2.16, not yet in a tagged release
 219                         # backport available for 2.15, but refused upstream due to RPC breakage.
 220                         "${FILESDIR}"/0001-kvm-use_guest_agent-QEMU-Guest-Agent-sup.stable-2.16.patch
 221                 )
 222         fi
 223         eapply "${PATCHES[@]}"
 224         # Upstream commits:
 225         # 4c3c2ca2a97a69c0287a3d23e064bc17978105eb
 226         # 24618882737fd7c189adf99f4acc767d48f572c3
 227         sed -i \
 228                 -e '/QuickCheck/s,< 2.8,< 2.8.3,g' \
 229                 cabal/ganeti.template.cabal
 230         # Neuter -Werror
 231         sed -i \
 232                 -e '/^if DEVELOPER_MODE/,/^endif/s/-Werror//' \
 233                 Makefile.am
 234
 235         # not sure why these tests are failing
 236         # should remove this on next version bump if possible
 237         for testfile in test/py/import-export_unittest.bash; do
 238                 printf '#!/bin/bash\ntrue\n' > "${testfile}"
 239         done
 240
 241         # take the sledgehammer approach to bug #526270
 242         grep -lr '/bin/sh' "${S}" | xargs -r -- sed -i 's:/bin/sh:/bin/bash:g'
 243
 244         eapply_user
 245
 246         [[ ${PV} =~ [9]{4,} ]] && ./autogen.sh
 247         rm autotools/missing
 248         eautoreconf
 249 }
 250
 251 src_configure () {
 252         # this is kind of a hack to work around the removal of the qemu-kvm wrapper
 253         local kvm_arch
 254
 255         if use amd64; then
 256                 kvm_arch=x86_64
 257         elif use x86; then
 258                 kvm_arch=i386
 259         elif use kvm; then
 260                 die "Could not determine qemu system to use for kvm"
 261         fi
 262
 263         econf --localstatedir=/var \
 264                 --sharedstatedir=/var \
 265                 --disable-symlinks \
 266                 --with-ssh-initscript=/etc/init.d/sshd \
 267                 --with-export-dir=/var/lib/ganeti-storage/export \
 268                 --with-os-search-path=/usr/share/${PN}/os \
 269                 $(use_enable restricted-commands) \
 270                 $(use_enable test haskell-tests) \
 271                 $(usex multiple-users "--with-default-user=" "" "gnt-daemons" "") \
 272                 $(usex multiple-users "--with-user-prefix=" "" "${USER_PREFIX}" "") \
 273                 $(usex multiple-users "--with-default-group=" "" "gnt-daemons" "") \
 274                 $(usex multiple-users "--with-group-prefix=" "" "${GROUP_PREFIX}" "") \
 275                 $(use_enable syslog) \
 276                 $(use_enable monitoring) \
 277                 $(usex kvm '--with-kvm-path=' '' "/usr/bin/qemu-system-${kvm_arch}" '') \
 278                 $(usex haskell-daemons "--enable-confd=haskell" '' '' '') \
 279                 --with-haskell-flags="-optl -Wl,-z,relro -optl -Wl,--as-needed" \
 280                 --enable-socat-escape \
 281                 --enable-socat-compress
 282 }
 283
 284 src_install () {
 285         emake V=1 DESTDIR="${D}" install
 286
 287         newinitd "${FILESDIR}"/ganeti.initd-r3 ${PN}
 288         newconfd "${FILESDIR}"/ganeti.confd-r2 ${PN}
 289
 290         if use kvm; then
 291                 newinitd "${FILESDIR}"/ganeti-kvm-poweroff.initd ganeti-kvm-poweroff
 292                 newconfd "${FILESDIR}"/ganeti-kvm-poweroff.confd ganeti-kvm-poweroff
 293         fi
 294
 295         # ganeti installs it's own docs in a generic location
 296         rm -rf "${D}"/{usr/share/doc/${PN},run}
 297
 298         sed -i "s:/usr/$(get_libdir)/${PN}/tools/burnin:burnin:" doc/examples/bash_completion
 299         newbashcomp doc/examples/bash_completion gnt-instance
 300         bashcomp_alias gnt-instance burnin ganeti-{cleaner,confd} \
 301                 h{space,check,scan,info,ail,arep,roller,squeeze,bal} \
 302                 gnt-{os,job,filter,debug,storage,group,node,network,backup,cluster}
 303
 304         use monitoring && bashcomp_alias gnt-instance mon-collector
 305
 306         dodoc INSTALL UPGRADE NEWS README doc/*.rst
 307
 308         docinto html
 309         dodoc -r doc/html/* doc/css/*.css
 310
 311         docinto examples
 312         dodoc doc/examples/{ganeti.cron,gnt-config-backup} doc/examples/*.ocf
 313
 314         docinto examples/hooks
 315         dodoc doc/examples/hooks/{ipsec,ethers}
 316
 317         insinto /etc/cron.d
 318         newins doc/examples/ganeti.cron ${PN}
 319
 320         insinto /etc/logrotate.d
 321         newins doc/examples/ganeti.logrotate ${PN}
 322
 323         # need to dodir rather than keepdir here (bug #552482)
 324         dodir /var/lib/${PN}
 325
 326         keepdir /var/log/${PN}/
 327         keepdir /usr/share/${PN}/${SERIES}/os/
 328         keepdir /var/lib/ganeti-storage/{export,file,shared}/
 329
 330         dosym ${SERIES} "/usr/share/${PN}/default"
 331         dosym ${SERIES} "/usr/$(get_libdir)/${PN}/default"
 332
 333         python_fix_shebang "${ED}" "${D}"/usr/"$(get_libdir)"/${PN}/${SERIES}
 334 }
 335
 336 pkg_postinst() {
 337         if use multiple-users; then
 338                 elog "You have enable multiple user support, the users for this must"
 339                 elog "be created. You can use the provided tool for this, which is"
 340                 elog "located at:"
 341                 elog "    /usr/$(get_libdir)/${PN}/tools/users-setup"
 342         fi
 343 }
 344
 345 src_test () {
 346         PATH="${S}/scripts:${S}/src:${PATH}" \
 347                 TMPDIR="/tmp" \
 348                 GANETI_MASTER="$(hostname -f)" \
 349                 emake check || die "emake check failed"
 350 }