app-cdr/gcdemu/gcdemu-3.2.3.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{6,7,8} )
   7
   8 inherit cmake-utils gnome2-utils python-single-r1 xdg-utils
   9
  10 DESCRIPTION="Gtk+ GUI for controlling cdemu-daemon"
  11 HOMEPAGE="https://cdemu.sourceforge.io"
  12 SRC_URI="https://download.sourceforge.net/cdemu/gcdemu/${P}.tar.bz2"
  13
  14 LICENSE="GPL-2+"
  15 SLOT="0"
  16 KEYWORDS="amd64 x86"
  17 IUSE=""
  18 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  19
  20 # librsvg for pixbuf-loader
  21 RDEPEND="${PYTHON_DEPS}
  22         app-cdr/cdemu-daemon:0/7
  23         $(python_gen_cond_dep '
  24                 dev-python/pygobject:3[${PYTHON_MULTI_USEDEP}]
  25         ')
  26         gnome-base/librsvg:2
  27         x11-libs/gdk-pixbuf[introspection]
  28         x11-libs/gtk+:3[introspection]
  29         x11-libs/libnotify[introspection]"
  30 DEPEND="
  31         dev-util/desktop-file-utils
  32         >=dev-util/intltool-0.21
  33         sys-devel/gettext
  34         virtual/pkgconfig"
  35
  36 DOCS=( AUTHORS README )
  37
  38 src_prepare() {
  39         cmake-utils_src_prepare
  40         python_fix_shebang src/gcdemu
  41 }
  42
  43 src_configure() {
  44         local mycmakeargs=( -DPOST_INSTALL_HOOKS=OFF )
  45         cmake-utils_src_configure
  46 }
  47
  48 pkg_postinst() {
  49         xdg_desktop_database_update
  50         gnome2_schemas_update
  51 }
  52
  53 pkg_postrm() {
  54         xdg_desktop_database_update
  55         gnome2_schemas_update
  56 }