app-arch/dump/dump-0.4.46-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 MY_P="${PN}-$(ver_rs 2 b)"
   7 S=${WORKDIR}/${MY_P}
   8 DESCRIPTION="Dump/restore ext2fs backup utilities"
   9 HOMEPAGE="http://dump.sourceforge.net/"
  10 SRC_URI="mirror://sourceforge/dump/${MY_P}.tar.gz"
  11
  12 LICENSE="BSD"
  13 SLOT="0"
  14 KEYWORDS="~alpha amd64 ~hppa ~ia64 ppc ppc64 sparc x86"
  15 # We keep uuid USE flag default dsiabled for this version. Don't forget
  16 # to default enable it for later versions as this is the upstream default.
  17 IUSE="bzip2 debug ermt libressl lzo readline selinux sqlite ssl static test uuid zlib"
  18 RESTRICT="!test? ( test )"
  19 REQUIRED_USE="
  20         ermt? ( ssl )
  21         ssl? ( zlib )
  22         test? ( sqlite? ( uuid ) )
  23 "
  24
  25 RDEPEND=">=sys-fs/e2fsprogs-1.27:=
  26         >=sys-libs/e2fsprogs-libs-1.27:=
  27         sys-apps/util-linux
  28         bzip2? ( >=app-arch/bzip2-1.0.2:= )
  29         zlib? ( >=sys-libs/zlib-1.1.4:= )
  30         lzo? ( dev-libs/lzo:2= )
  31         sqlite? ( dev-db/sqlite:3= )
  32         ermt? (
  33                 !libressl? ( dev-libs/openssl:0= )
  34                 libressl? ( dev-libs/libressl:0= )
  35         )
  36         ssl? (
  37                 !libressl? ( dev-libs/openssl:0= )
  38                 libressl? ( dev-libs/libressl:0= )
  39         )
  40         readline? (
  41                 sys-libs/readline:0=
  42                 sys-libs/ncurses:=
  43                 static? ( sys-libs/ncurses:=[static-libs] )
  44         )"
  45 DEPEND="${RDEPEND}
  46         virtual/os-headers"
  47 BDEPEND="
  48         virtual/pkgconfig
  49 "
  50
  51 PATCHES=(
  52         "${FILESDIR}"/${P}-openssl11.patch
  53 )
  54
  55 src_configure() {
  56         local myeconfargs=(
  57                 --with-dumpdatespath=/etc/dumpdates
  58                 --with-rmtpath='$(sbindir)/rmt'
  59                 --enable-blkid
  60                 $(use_enable bzip2)
  61                 $(use_enable debug)
  62                 $(use_enable ermt)
  63                 $(use_enable lzo)
  64                 $(use_enable readline)
  65                 $(use_enable selinux)
  66                 $(use_enable sqlite)
  67                 $(use_enable ssl)
  68                 $(use_enable static static-progs)
  69                 $(use_enable uuid)
  70                 $(use_enable zlib)
  71         )
  72         econf "${myeconfargs[@]}"
  73 }
  74
  75 src_install() {
  76         default
  77         mv "${ED}"/usr/sbin/{,dump-}rmt || die
  78         mv "${ED}"/usr/share/man/man8/{,dump-}rmt.8 || die
  79         use ermt && newsbin rmt/ermt dump-ermt
  80
  81         dodoc KNOWNBUGS MAINTAINERS REPORTING-BUGS
  82         dodoc -r examples
  83 }
  84
  85 pkg_postinst() {
  86         if [[ -z ${REPLACING_VERSIONS} ]] ; then
  87                 ewarn "app-arch/dump installs 'rmt' as 'dump-rmt'."
  88                 ewarn "This is to avoid conflicts with app-arch/tar 'rmt'."
  89         fi
  90 }