app-accessibility/at-spi2-core/at-spi2-core-2.34.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit gnome.org meson multilib-minimal systemd virtualx xdg
   7
   8 DESCRIPTION="D-Bus accessibility specifications and registration daemon"
   9 HOMEPAGE="https://wiki.gnome.org/Accessibility"
  10
  11 LICENSE="LGPL-2.1+"
  12 SLOT="2"
  13 IUSE="X gtk-doc +introspection"
  14 KEYWORDS="~alpha amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ppc ppc64 ~s390 ~sparc x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
  15
  16 RDEPEND="
  17         >=sys-apps/dbus-1.5[${MULTILIB_USEDEP}]
  18         >=dev-libs/glib-2.36:2[${MULTILIB_USEDEP}]
  19         introspection? ( >=dev-libs/gobject-introspection-1.54.0:= )
  20         X? (
  21                 x11-libs/libX11[${MULTILIB_USEDEP}]
  22                 x11-libs/libXtst[${MULTILIB_USEDEP}]
  23                 x11-libs/libXi[${MULTILIB_USEDEP}]
  24         )
  25 "
  26 DEPEND="${RDEPEND}"
  27 BDEPEND="
  28         >=dev-util/meson-0.50.0
  29         dev-util/glib-utils
  30         gtk-doc? (
  31                 >=dev-util/gtk-doc-1.25
  32                 app-text/docbook-xml-dtd:4.3 )
  33         >=sys-devel/gettext-0.19.8
  34         virtual/pkgconfig[${MULTILIB_USEDEP}]
  35 "
  36
  37 PATCHES=(
  38         # disable teamspaces test since that requires Novell.ICEDesktop.Daemon
  39         "${FILESDIR}/${PN}-2.0.2-disable-teamspaces-test.patch"
  40 )
  41
  42 multilib_src_configure() {
  43         local emesonargs=(
  44                 -Dsystemd_user_dir="$(systemd_get_userunitdir)"
  45                 -Ddocs=$(multilib_native_usex gtk-doc true false)
  46                 -Dintrospection=$(multilib_native_usex introspection)
  47                 -Dx11=$(usex X)
  48         )
  49         meson_src_configure
  50 }
  51
  52 multilib_src_compile() {
  53         meson_src_compile
  54 }
  55
  56 multilib_src_test() {
  57         virtx meson_src_test
  58 }
  59
  60 multilib_src_install() {
  61         meson_src_install
  62 }