www-servers/nginx-unit/nginx-unit-1.5.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=(python2_7 python3_{3,4,5,6,7})
   7
   8 inherit python-single-r1
   9
  10 MY_P="unit-${PV}"
  11 DESCRIPTION="A dynamic web and application server"
  12 HOMEPAGE="https://unit.nginx.org"
  13 SRC_URI="https://unit.nginx.org/download/${MY_P}.tar.gz -> ${P}.tar.gz"
  14
  15 LICENSE="Apache-2.0"
  16 SLOT="0"
  17 KEYWORDS="~amd64"
  18 MY_USE="perl python ruby"
  19 MY_USE_PHP="php5-6 php7-0 php7-1 php7-2"
  20 IUSE="${MY_USE} ${MY_USE_PHP}"
  21 REQUIRED_USE="|| ( ${IUSE} ) python? ( ${PYTHON_REQUIRED_USE} )"
  22
  23 DEPEND="perl? ( dev-lang/perl:= )
  24         php5-6? ( dev-lang/php:5.6[embed] )
  25         php7-0? ( dev-lang/php:7.0[embed] )
  26         php7-1? ( dev-lang/php:7.1[embed] )
  27         php7-2? ( dev-lang/php:7.2[embed] )
  28         python? ( ${PYTHON_DEPS} )
  29         ruby? ( dev-lang/ruby:= )"
  30 RDEPEND="${DEPEND}"
  31 S="${WORKDIR}/${MY_P}"
  32
  33 pkg_setup() {
  34         use python && python-single-r1_pkg_setup
  35 }
  36
  37 src_configure() {
  38         ./configure \
  39                 --control=unix:/run/${PN}.sock \
  40                 --ld-opt="${LDFLAGS}" \
  41                 --log=/var/log/${PN} \
  42                 --modules=$(get_libdir)/${PN} \
  43                 --pid=/run/${PN}.pid \
  44                 --prefix=/usr \
  45                 --state=/var/lib/${PN} || die "Core configuration failed"
  46         for flag in ${MY_USE} ; do
  47                 if use ${flag} ; then
  48                         ./configure ${flag} || die "Module configuration failed: ${flag}"
  49                 fi
  50         done
  51         for flag in ${MY_USE_PHP} ; do
  52                 if use ${flag} ; then
  53                         local php_slot="/usr/$(get_libdir)/${flag/-/.}"
  54                         ./configure php \
  55                                 --module=${flag} \
  56                                 --config=${php_slot}/bin/php-config \
  57                                 --lib-path=${php_slot}/$(get_libdir) || die "Module configuration failed: ${flag}"
  58                 fi
  59         done
  60 }
  61
  62 src_install() {
  63         default
  64         diropts -m 0770
  65         keepdir /var/lib/${PN}
  66         newinitd "${FILESDIR}/${PN}.initd" ${PN}
  67 }