sci-electronics/qelectrotech/qelectrotech-0.61.ebuild

   1 # Copyright 1999-2018 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit gnome2-utils qmake-utils xdg-utils
   7
   8 MY_P=${PN}-${PV%0}-src
   9
  10 DESCRIPTION="Qt5 application to design electric diagrams"
  11 HOMEPAGE="https://qelectrotech.org/"
  12 SRC_URI="https://download.tuxfamily.org/qet/tags/20180823/${MY_P}.tar.gz"
  13
  14 LICENSE="CC-BY-3.0 GPL-2+"
  15 SLOT="0"
  16 KEYWORDS="amd64 x86"
  17 IUSE="doc"
  18
  19 RDEPEND="
  20         dev-qt/qtconcurrent:5
  21         dev-qt/qtcore:5
  22         dev-qt/qtgui:5
  23         dev-qt/qtnetwork:5
  24         dev-qt/qtprintsupport:5
  25         dev-qt/qtsql:5[sqlite]
  26         dev-qt/qtsvg:5
  27         dev-qt/qtwidgets:5
  28         dev-qt/qtxml:5
  29 "
  30 DEPEND="${RDEPEND}
  31         doc? ( app-doc/doxygen )
  32 "
  33
  34 S=${WORKDIR}/${MY_P}
  35
  36 DOCS=( CREDIT ChangeLog README )
  37 PATCHES=( "${FILESDIR}/${PN}-0.3-fix-paths.patch" )
  38
  39 src_configure() {
  40         eqmake5 ${PN}.pro
  41 }
  42
  43 src_install() {
  44         emake INSTALL_ROOT="${D}" install
  45
  46         einstalldocs
  47
  48         if use doc; then
  49                 doxygen Doxyfile || die
  50                 dodoc -r doc/html
  51         fi
  52 }
  53
  54 pkg_postinst() {
  55         xdg_desktop_database_update
  56         xdg_mimeinfo_database_update
  57         gnome2_icon_cache_update
  58 }
  59
  60 pkg_postrm() {
  61         xdg_desktop_database_update
  62         xdg_mimeinfo_database_update
  63         gnome2_icon_cache_update
  64 }