net-mail/mpop/mpop-1.4.7.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 DESCRIPTION="A small, fast, and portable POP3 client"
   7 HOMEPAGE="https://marlam.de/mpop/"
   8 SRC_URI="https://marlam.de/mpop/releases/${P}.tar.xz"
   9
  10 LICENSE="GPL-3"
  11 SLOT="0"
  12 KEYWORDS="~amd64 ~arm ~x86"
  13 IUSE="gnutls idn libressl gnome-keyring nls sasl ssl vim-syntax"
  14
  15 RDEPEND="
  16         idn? ( net-dns/libidn2 )
  17         gnome-keyring? ( app-crypt/libsecret )
  18         nls? ( virtual/libintl )
  19         sasl? ( virtual/gsasl )
  20         ssl? (
  21                 gnutls? ( net-libs/gnutls:0=[idn?] )
  22                 !gnutls? (
  23                         !libressl? ( dev-libs/openssl:0= )
  24                         libressl? ( dev-libs/libressl:0= )
  25                 )
  26         )"
  27 DEPEND="${RDEPEND}
  28         nls? ( sys-devel/gettext )
  29         virtual/pkgconfig"
  30
  31 REQUIRED_USE="gnutls? ( ssl )"
  32
  33 DOCS="AUTHORS ChangeLog NEWS NOTES README THANKS"
  34
  35 src_configure() {
  36         econf \
  37                 $(use_enable nls) \
  38                 $(use_with ssl tls $(usex gnutls "gnutls" "openssl")) \
  39                 $(use_with sasl libgsasl) \
  40                 $(use_with idn libidn) \
  41                 $(use_with gnome-keyring libsecret)
  42 }
  43
  44 src_install() {
  45         default
  46
  47         if use vim-syntax ; then
  48                 insinto /usr/share/vim/vimfiles/syntax
  49                 doins scripts/vim/mpop.vim
  50         fi
  51 }